Using global command on Quickfix entries [duplicate]

Question

I find and replace a pattern in all the files in my project (which is a big one). After the search is done, quickfix window is opened with the matches. The matches are in different files in different directories/sub-directories.

When I want to replace all the matches in the quickfix list, I run the following command:

:cfdo %s/old/new/g

Sometimes I want to replace only the matches in files that are in a specific directory (e.g., DPUST) and don't touch the matches in the files in the other directories.

I tried running the following command while the cursor is in quickfix window:

:g/DPUST/cfdo %s/old/new/gc

But I found that this tries to replace the matches in every quickfix entry.

What am I missing to get this to work?

Answer 1

Update: New official vim plugin cfilter

Since 21.8.2018 (patch: 8.1.0311) the plugin cfilter is distributed with vim in $VIMRUNTIME. It is documented under :h cfilter-plugin.

Load plugin cfilter when needed or load it always in your vimrc

:packadd cfilter

Using abbreviations in case of a vanilla vim this can be as short as :pa c<tab><cr>.

Filter quickfix list with

:Cfilter DPUST

Again, using abbreviations in case of vanilla vim the command :Cfilter can be shortened to :Cf.

Run :cfdo

:cfdo %s/old/new/g

---

Original Answer

As far as I see it, :cfdo works on the quickfix list. This will not be changed by prefixing the command with :g/DPUST/. You could have come up with :v/DPUST/delete and then :cfdo %s/old/new/gc. However, the quickfix list cannot be changed easily. There are quite a few plugins which provide support for this

• vim-lister :Qfilter DPUST
• vim-qf :Keep DPUST
• QFGrep :QFGrepPat DPUST

Following plugins allow to remove lines from the quickfix list with vim commands e.g. :v/DPUST/d

• quickfix-reflector
• vim-qfedit

If do not want a full plugin, add following lines to your vimrc to get the command :Qfilter

" From https://github.com/dhruvasagar/dotfiles/blob/master/vim/plugin/filter_list.vim
function! s:FilterList(list, bang, pattern)
  let list = deepcopy(a:list)
  let [cmp, and_or] = a:bang ? ['!~#', '&&'] : ['=~#', '||']
  return filter(a:list, "bufname(v:val.bufnr) " . cmp . " a:pattern " . and_or . " v:val.text " . cmp . " a:pattern")
endfunction
function! s:FilterQuickfixList(bang, pattern)
  call setqflist(s:FilterList(getqflist(), a:bang, a:pattern))
endfunction
command! -bang -nargs=1 -complete=file Qfilter call s:FilterQuickfixList(<bang>0, <q-args>)

This has already been asked:

• Is it possible to grep Vim's quickfix?
• How do I make list of search results editable?
• Quickfix list, how to add and remove entries

Note grep stands for global/regular expression/print. Questions using the term grep or global are referring possibly to identical tasks.

Answer 2

If you need the quickfix list to decide what directory you want to use/exclude why do you not just execute another search just before the :cfdo? Like this:

1. first you search :RIPGREP search-term
2. look at the result and decide what to include
3. rerun the last command with some explicit directory :↑some-dir
4. then run your replace command: :cfdo %s/foo/bar/gc

If your custom :RIPGREP command supports command chaining you can type 3 and 4 on one line and if you use this really often you can try to turn it into a custom command (retrieve the last command from history with histget()).