How to automatically turn off "hlsearch" after I'm done searching?

Question

I love the "hlsearch" setting, but after I'm done searching, I find it obnoxious. Especially if I search for something that has a lot of matches. I know that I can turn this off with

:set nohlsearch

But this takes a whole 16 keystrokes, and even more annoyingly, I have to turn it back on for my next search with

:set hlsearch    

Is there a way I can have hlsearch automatically toggle on when I start searching, and off when I am done searching? For example, if I enter insert mode, or modify the text, have hlsearch turn off without any additional keystrokes?

Answer 1

There is a much more convenient way. Rather than using

:set nohlsearch

which actually turns the hlsearch setting off, use

:nohls

This will only turn hlsearch off until you search again. From :help nohls

                 *'hlsearch'* *'hls'* *'nohlsearch'* *'nohls'*
'hlsearch' 'hls'    boolean (default off)
            global
            {not in Vi}
            {not available when compiled without the
            |+extra_search| feature}

    ...

    When you get bored looking at the highlighted matches, you can turn it
    off with |:nohlsearch|.  This does **not change the option value**, as
    soon as you use a search command, the highlighting comes back.

However, this solution isn't perfect, since you still have to type out :nohls which is pain to do after every search. You can get around this with a mapping, e.g.

nnoremap <esc><esc> :silent! nohls<cr>

But there is an even better solution! haya14busa/incsearch.vim. This is, at least in my opinion, an essential vim plugin. The main feature is that all search matches are highlighted in real time, as you are typing out your regex. For example:

However, a secondary feature that is also provided is the option to immediately toggle hlsearch on and off when you start/stop searching. To enable this feature, you will have to add

set hlsearch
let g:incsearch#auto_nohlsearch = 1
map n  <Plug>(incsearch-nohl-n)
map N  <Plug>(incsearch-nohl-N)
map *  <Plug>(incsearch-nohl-*)
map #  <Plug>(incsearch-nohl-#)
map g* <Plug>(incsearch-nohl-g*)
map g# <Plug>(incsearch-nohl-g#)

to your .vimrc.

If you have any other n mappings, you will have to turn these off. For example, I used to have

nnoremap n nzz
nnoremap N Nzz

These two mappings are not compatible with eachother!

Answer 2

vim-cool is a simple plugin that does just this.

Vim-cool disables search highlighting when you are done searching and re-enables it when you search again.

It works without remapping by using the CursorMoved and InsertEnter autocommands.

Answer 3

I have found it more intuitive to remap the Ctrl-L repaint to include :nohls:

nnoremap <C-L> :nohls<cr><C-L>

Answer 4

I use <Leader><Enter> as a shortcut to :noh. (My leader is ,, so it's pretty close)

This will turn off the highlights until your next search.

Answer 5

As you've already noted in your own answer, it's far more efficient to turn off highlighting with the :nohlsearch command (which can be abbreviated to :noh) rather than turning off the entire feature and then turning it back on the next time you search.

If you want to switch off highlighting every time you use i to enter insert mode, you can create a simple mapping to do so:

:nnoremap i :noh<cr>i

It's left as an exercise for the reader to create similar mappings for other commands where they want highlighting switched off.

More recent versions of Vim have an InsertEnter autocommand which you might think could be used to easily create a cleaner implementation of switching off highlighting, but unfortunately, the :nohlsearch command has no effect within an autocommand. A possible workaround is instead to reset the search pattern when entering insert mode, but that obviously has side effects you may not desire:

augroup ClearSearch
  autocmd!
  autocmd InsertEnter * let @/ = ''
augroup END

There is, however, a better technique, which is to use feedkeys from the autocommand. This is what the vim-cool plugin mentioned in Jon Parise's answer uses.

Answer 6

It might sound stupid or naive, but what I do when I want to stop the highlighting is I search for a random string that (virtually certainly) is not present in the document. Something like this:

/skljdfhadhfs

Granted, it does take a few key strokes, but they are really random, so they can be typed in no time.

Answer 7

I'm surprised that the following solution hasn't been posted:

augroup vimrc-incsearch-highlight
  autocmd!
  autocmd CmdlineEnter /,\? :set hlsearch
  autocmd CmdlineLeave /,\? :set nohlsearch
augroup END

Answer 8

I use <Leader><Enter> as a shortcut to :hls and have my leader set as space.

let mapleader = "\<Space>"
nmap <silent> <leader><Esc> :set hls!<cr>

After searching an item will be highlighted, to turn it off, hit <Space><Esc>. And if you decide you want to redisplay the search results, hit <Space><Esc>. The hls! means map this key binding to toggle the setting for hls (shorthand for hlsearch, i.e. search result highlighting) (so the ! toggles the setting right before it).

Answer 9

I know I'm a little bit late, but there is a plugin called is.vim. Maybe it can be useful for someone, here is the link: https://vimawesome.com/plugin/is-vim

Answer 10

Remark: turning off hlsearch (as in this answer) won't clear the search register.

It means that you can still jump to next/prev matches but with no highlights which could be annoying for some users as it was for me.

To clear the search register itself and the highlight in one command you may use:

:let @/ = ""

Answer 11

i use buildin vim function to solve it, just add this to .vimrc:

set hls
augroup clearhlsearch
 autocmd!
 autocmd InsertEnter,VimEnter,CursorHold * :let @/=""
augroup END

description: set highlight search to enable set hls make auto command group clearhlsearch, line 1 clear previous autocommand buffer with autocmd!, line 2 set search buffer to " " when open vim VimEnter or exit from insert mode InsertLeave, or cursor not move CursorHold (it depend to set updatetime) you can get my vim config in here Wahyu's dotfile

Answer 12

Add this macro to your .vimrc

map #h :set hls!<CR>

This will allow you to toggle hilighting with #h