How to disable search highlight automatically after searching?

Question

Search highlight is very convenient for me when I'm searching, but after I'm done with doing stuff with search matches it's distracting to me, so I'm using :noh mapped to F3 everytime I've done what I needed to do with matches.

I'd like to automate this process as it is very annoying to me (this is what vim is about right?). Is it possible to turn off highlighting if n or N isn't pressed for a couple of seconds?

Edit1

Guys, don't bother explain to me how YOU use vim (toggle highlight in insert mode etc). I know exactly what I want and asked precise question. I know you're trying to be helpful, but you're not, sorry.

Answer 1

I recently wrote a small plugin that seems to do exactly what you want.

It works by remapping search-related normal mode commands /?nN*#g*g# and <CR> in command-line mode, and installing a cursorMoved autocommand.

Answer 2

I actually like to keep the search highlighting, but find it annoying in insert mode. This is something I use in my config to toggle it off when editing:

" Removes the search highlight on insert mode and restores it in normal mode
function! s:toggle_highlight()
  if exists('b:last_hlsearch')
    let &l:hlsearch = b:last_hlsearch
    unlet b:last_hlsearch
  elseif &l:hlsearch
    let b:last_hlsearch = &l:hlsearch
    setlocal nohlsearch
  endif
endfunction

augroup vimrc_search
  autocmd!
  autocmd InsertEnter * call s:toggle_highlight()
  autocmd InsertLeave * call s:toggle_highlight()
augroup END

I also use this key map so I don't have to move my hands from the home row:

nnoremap <leader><space> :nohlsearch<cr>

With faster access to :nohlsearch, I serve as a much better judge for determining when search highlighting is not useful.

Answer 3

If your vim has the +timers functionality you can use them like so:

let s:current_timer = -1

function! DisableHL(timerId)
  set nohlsearch
endfunction

function! ResetTimer()
  if s:current_timer > -1
    call timer_stop(s:current_timer)
  endif
  let s:current_timer = timer_start(2000, 'DisableHL')
endfunction


nnoremap <silent> n n:call ResetTimer()<CR>