Why does this <Esc> normal mode mapping affect startup?

Question

I'm experiencing a weird problem with a normal mode mapping of Esc.

If you create the file escmapvimrc with the contents:

set nocompatible
set showcmd " Doesn't affect the problem: just makes it easier to see
nnoremap <Esc> :noh<CR><esc>

And then start vim using this vimrc:

vim --noplugin -u escmapvimrc

Then vim will start in operator-pending mode with a c command waiting for further input, displaying an empty file, and with the command-line displaying :noh.

If you remove the nnoremap line, then the problem goes away.

If you debug and step through everything you get the following output:

Entering Debug mode.  Type "cont" to continue.
/[...]/escmapvimrc
line 1: set nocompatible
>s
/[...]/escmapvimrc
line 2: set showcmd " Doesn't affect the problem: just makes it easier to see
>s
/[...]/escmapvimrc
line 3: nnoremap <Esc> :noh<CR><esc>
>s
/[...]/escmapvimrc
line 4: End of sourced file
>s
Press ENTER or type command to continue

After you press enter, the Vim startup screen is displayed, and underneath:

Entering Debug mode.  Type "cont" to continue.
cmd: noh
>s

The Vim startup screen then disappears, and you're in operator-pending mode, as described above.

What's going on?

EDIT: Behaviour is as described in Vim 7.3. In Vim 7.4.52, the nmap causes Vim to start up in Replace mode when starting Vim without a file. (If Vim 7.4.52 is started with a file, however, it also starts up with a c-command underway.) Either way, the problem goes away when the nmap is removed.

Answer 1

Vim sends during startup some special terminal codes (that usually contain the <esc> key) to determine several things (colors, bs,...) If you mapped <esc> this will most likely confuse the parser of the return codes and weird things can happen.

Therefore, use your above map only after everything has been setup correctly (e.g. via a VimEnter autocommand).

Answer 2

The Linux terminal uses ANSI escape sequences (i.e. strings of characters starting with <Esc>) to send special keys to Vim, and as part of the communication protocol with which the application queries for its capabilities. Your mapping interferes with that, and thereby leads to these "strange" behaviors.

Therefore, don't map <Esc>. Use another key. The problem is less pronounced in GVIM, but I wouldn't recommend it there, neither.

Answer 3

I tried setting up an autocommand to set the mapping later on in startup, but the problem still occurred.^*

I eventually created an autocommand to occur the first time I enter Insert mode. This is obviously not a perfect solution, but for me it'll work most of the time, and it seems to be the best I can do:

FURTHER UPDATE: If you’re using a vaguely recent version of Vim, @BLayer’s answer to this duplicate question is a much nicer solution. (It uses the timers feature to delay setup of the mapping instead of my Insert mode hack.)

UPDATE: After using the longer version below without issue for a few years, I decided it was possibly slightly over-engineered, and since then I've used this much simpler version, which instead just resets the mapping every time you enter insert mode:

augroup escape_mapping
  autocmd!
  autocmd InsertEnter * call s:setupEscapeMap()
augroup END

function! s:setupEscapeMap()
  nnoremap <Esc> :noh<CR><Esc>
endfunction

The mapping doesn't need to be reset every time you enter insert mode, but it also doesn't do any harm for Vim to do so.

ORIGINAL VERSION:

if !exists('g:escape_mapped')  " Only need to set the mapping up once.
  augroup escape_mapping
    autocmd!
    " Create the autocommand, to fire when Insert mode is entered
    autocmd InsertEnter * call s:setupEscapeMap()
  augroup END
endif

function! s:setupEscapeMap()
  " Actually create the mapping
  nnoremap <Esc> :noh<CR><Esc> 

  " Now the map exists, so we won't ever need the autocommand again.
  let g:escape_mapped = 1

  " Tidy up the autocommand and group
  autocmd! escape_mapping InsertEnter *
  augroup! escape_mapping
endfunction

^{* I tried attaching it to various events: VimEnter, BufReadPost, BufWinEnter, and even CursorMoved(!), but these all seem to fire too early.}

Answer 4

I have found that mapping ESC in /home/.vimrc will open vim with replace command. Instead, I did the exact mapping but in /etc/vim/vimrc file and the mapping is executed successfully without the popping of replace command at startup.

Answer 5

Try this:

augroup escape_mapping
  autocmd TermResponse * nnoremap <Esc> :noh<CR><esc>
augroup end

cf https://stackoverflow.com/a/16027716/400545