Open the same file in two vertical splits: one editable, the other not

Question

I need to refactor some paragraphs from an article.

I would like to have:

• One split with the original version (not editable)
• Another split with the document to edit

Is it possible?

Answer 1

Here is a simpler solution (inspired by the other one)

:let ft=&ft
:vertical new
:setlocal bufhidden=wipe buftype=nofile nobuflisted noswapfile
:read ++edit #
:silent 0d_
:setlocal nomodifiable
:execute "set ft=" . ft
:wincmd p

It:

1. Copy the file type of the current buffer
2. Create a vertical split
3. Set the corresponding buffer a scratch buffer
4. Read the text into the buffer
5. Set the corresponding buffer non-modifiable
6. Set the file type of the new buffer
7. Delete the original blank line of the scratch buffer (optional)
8. Move back to the original split (optional)

Answer 2

To edit safely a file you could do:

1. Make the file read-only [optional] (depend of your OS)
2. Open the file in Vim
3. Make the buffer non read-only [optional] (:set noreadonly)
4. Use the Diff custom command to compare with the version saved on disk (see bottom of the question for its definition)
5. Make your modifications

6. Make the file non-read-only (depend of your OS)
7. Save the version using :w! [optional]

function! Diff(spec)
    vertical new
    setlocal bufhidden=wipe buftype=nofile nobuflisted noswapfile
        let cmd = "++edit #"
    if len(a:spec)
        let cmd = "!git -C " .. shellescape(fnamemodify(finddir('.git', '.;'), ':p:h:h')) .. " show " .. a:spec .. ":#"
    endif
    execute "read " .. cmd
    silent 0d_
    diffthis
    wincmd p
    diffthis
endfunction
command! -nargs=? Diff call Diff(<q-args>)

Remark: If you don't want the two buffer to be compared we can simplify the solution (by dropping the diffthis calls)