Open multiple files in tabs from Explore mode

Question

While navigating file system in :Explore mode, is it possible to select and open multiple files, each in a new tab?

Edit:

I ended up using a function proposed by Jair López, because it works pretty much as I envisioned it, although statox provided a good explanation for built-in netrw mechanics.

For consistency, I also added a normal mode mapping to make ShiftTT open a new tab, while keeping netrw tab in focus. It simplifies opening tabs for multiple files that aren't listed consecutively.

autocmd Filetype netrw nmap <buffer> <silent> TT VT

Answer 1

Let's Vim do it for you. You can put the following code at the end of your vimrc file:

function! NetrwOpenMultiTab(current_line,...) range
   " Get the number of lines.
   let n_lines =  a:lastline - a:firstline + 1

   " This is the command to be built up.
   let command = "normal "

   " Iterator.
   let i = 1

   " Virtually iterate over each line and build the command.
   while i < n_lines
      let command .= "tgT:" . ( a:firstline + i ) . "\<CR>:+tabmove\<CR>"
      let i += 1
   endwhile
   let command .= "tgT"

   " Restore the Explore tab position.
   if i != 1
      let command .= ":tabmove -" . ( n_lines - 1 ) . "\<CR>"
   endif

   " Restore the previous cursor line.
   let command .= ":" . a:current_line  . "\<CR>"

   " Check function arguments
   if a:0 > 0
      if a:1 > 0 && a:1 <= n_lines
         " The current tab is for the nth file.
         let command .= ( tabpagenr() + a:1 ) . "gt"
      else
         " The current tab is for the last selected file.
         let command .= (tabpagenr() + n_lines) . "gt"
      endif
   endif
   " The current tab is for the Explore tab by default.

   " Execute the custom command.
   execute command
endfunction

" Define mappings.
augroup NetrwOpenMultiTabGroup
   autocmd!
   autocmd Filetype netrw vnoremap <buffer> <silent> <expr> t ":call NetrwOpenMultiTab(" . line(".") . "," . "v:count)\<CR>"
   autocmd Filetype netrw vnoremap <buffer> <silent> <expr> T ":call NetrwOpenMultiTab(" . line(".") . "," . (( v:count == 0) ? '' : v:count) . ")\<CR>"
augroup END

Restart Vim and then you can:

1. Open Netrw (e.g., with :Explore)
2. Move the cursor to the first file.
3. Enter Line-wise Visual mode by hitting Shift-V
4. Hit J (That's not Shift-J, just in case) as much as you need to.
5. Hit T

Advantages

• You don't need to add any plugin
• It doesn't stuff the arglist
• You'll preserve the order of the buffer list and tabs
• You can choose which tab will be the current one by using or not using a count in the mapping.

Explanation

There's a lot going on here so if you're in doubt, just let me know. Let's say the directory you open with :Explore is as follows:

../
./
a.txt
b.txt
c.txt
d.txt

And the cursor is on file a.txt and next, you press Shift-V and move the cursor to the line with d.txt. You can hit:

• T to open each file in a tab and select the file d.txt as the current tab
• 1T to open each file in a tab and select the file a.txt as the current tab
• 2T to open each file in a tab and select the file b.txt as the current tab
• And so on

Or you can hit:

• Shift-T to open each file in a tab and keep the current tab.
• 1Shift-T to do the same as 1T
• 2Shift-T to do the same as 2T

The differences between Shift-T and T are:

• T select the last selected file as the current tab by default
• Shift-T keeps the current tab by default

Answer 2

From :h netrw-t:

BROWSING WITH A NEW TAB             netrw-t

Normally one enters a file or directory using the <cr>.  The "t" map
allows one to open a new window holding the new directory listing or file in
a new tab.

So in the netrw window simply press t when your cursor is on the file or on the directory you want to open in the new tab.

---

To do that with multiple files you need to mark them, put them in the arglist and then use the arg list to open the tabs.

To mark a file in a netrw window use mf.

Once the files are marked put them in the arglist with ma.

Then simply use :argdo tabnew.

Edit To reduce the number of keypresses you can add the following line in your .vimrc:

autocmd Filetype netrw nmap <buffer> <F5> ma:argdo tabnew<CR>

This is an autocommand which is executed when you open a netrw buffer (FileType netrw) and creates a mapping only in this buffer which will put the marked files in the arglist and issue the command :argdo tabnew.

With that you can simply mark your files with mf and use F5 (or another key if you prefer) to open the files in new tabs.

---

See

• :h netrw-mf
• :h netrw-ma
• :h :argdo
• :h arglist

Answer 3

If you don't mind installing a plugin, you could use dirvish.

Once the directory opened, visually select the files (e.g. with VG) and press t to open in a tab.