How to wait for user input in the middle of a mapping?

Question

I want to make a mapping that does the following:

nnoremap <F1> oHello, (user inputs their name. Ex. Jason). You have a very nice name.<ESC>

This mapping should make a non-recursive map to F1 that starts a new line in insert mode. Next it types "Hello, " then waits for the user to type their name and then enter or some other signal command to say they are done. After that input the map moves forward and completes the statement with "You have a very nice name." then exits insert mode with ESC.

Answer 1

You can use a mapping with the <expr> flag to achieve this. Mappings with the <expr> flag will evaluate the right hand side of the mapping as an expression and then apply the result as key strokes. This can be combined with the input() function to achieve what you want. Here is your mapping implemented with these features:

nnoremap <expr> <F1> "oHello, " . input("Please give your name: ") . ". You have a very nice name.\<ESC>"

Here is a break down of what happens:

• nnoremap <expr> - create a non-recursive expr mapping
• <F1> - the key you press to activate the mapping
• "oHello, " . input("Please give you name: ") . ". You have a very nice name.\<ESC>" - concatenates the result of the input function with the rest of the mapping. It is necessary to escape <ESC> because if you don't, it won't be interpreted as the escape key.

See :help input() and :help :map-<expr> for more.

Answer 2

By calling a user-defined function, a mapping that inserts "Hello, " before prompting for the user's name can be achieved:

function s:InputName()
    call inputsave()
    let g:name = input("Your name please: ")
    call inputrestore()
endfunction
nnoremap <F1> oHello, <C-\><C-o>:call <SID>InputName()<CR><C-r>=name<CR>. You have a nice name.<ESC>

This answer (with minor differences) was first shared as a link in a comment by @saginaw to the answer by @EvergreenTree, but I had essentially reproduced that answer (with a lot of reading :help pages and Googling) before clicking the link. This seems a distinct answer, from that of @EvergreenTree

As @saginaw pointed out, :help input() essentially documents this function-based solution, but @saginaw added the script-local function syntax (s: to the definition, and <sid> to the call).

This mapping uses insert special keys, including <C-\><C-o> (see :help i_CTRL-\_CTRL-O) and and <C-R>= (see :help i_CTRL-R_=).