Moving to special marks inside opfunc

Question

I'm trying to write a opfunc which surrounds selected motion with two stars (bold in Markdown):

nnoremap <localleader>b :set opfunc=BoldIt<CR>g@
function! BoldIt(type, ...)
    execute "normal! `[i**"
    execute "normal! `]a**"
endfunction

According to :map-operator info:

• [ mark denotes start of text
• ] mark denotes end of text

In my function just one of the marks works. I mean, if I comment either of the execute lines, the other one does the job correctly, as supposed to.

However, when run as shown, stars end in the same position. It's just like if one of the mark get lost. What I'm missing?

Answer 1

What I'm missing?

:h '] "To the last character of the previously changed or yanked text."

You must keep marks intact until you've done with all of them. Maybe :lockmarks or setline() or whatever.

Answer 2

@Matt is correct. You have effectively changed the last change marks which is why your approach can not work.

I would suggest you use c and <c-r> to paste/put the last deleted/yanked text to do your star-surrounding. e.g. c**<c-r>"**

I would also recommend following the technique/example laid out by Vim's help (See :h g@)

nnoremap <expr> <localleader>b BoldIt()
xnoremap <expr> <localleader>b BoldIt()
function! BoldIt(...)
    if !a:0
      set opfunc=BoldIt
      return 'g@'
    endif
    let type = a:1

    let sel_save = &selection
    let reg_save = @@
    let reg_type = getregtype('"')
    let cb_save = &clipboard
    let visual_marks_save = [getpos("'<"), getpos("'>")]

    let commands = {}
    let commands['line'] = "'[v']g_c**\<c-r>\"**\<esc>"
    let commands['char'] = "`[v`]c**\<c-r>\"**\<esc>"
    let commands['block'] = "`[\<c-v>`]c**\<c-r>\"**\<esc>"

    try
      set clipboard= selection=inclusive
      let cmd = 'noautocmd keepjumps normal! '
      let cmd .= get(commands, type, '')
      silent exe cmd
    finally
      call setreg('"', reg_save, reg_type)
      call setpos("'<", visual_marks_save[0])
      call setpos("'>", visual_marks_save[1])
      let &clipboard = cb_save
      let &selection = sel_save
    endtry
endfunction

Note: This may require a newer version of Vim (tested on Vim 8.2.2681)