Is it possible to remove an entry from the undo history?

Question

I have these lines in my .vimrc to help with indentation:

autocmd BufReadPost * set noexpandtab | retab! 4
autocmd BufWritePre * set expandtab | retab! 4
autocmd BufWritePost * set noexpandtab | retab! 4

However, they create a lot of noise in the undo history. Since they essentially do nothing from the user's perspective, I'd like to remove them from the history or at the very least squash them somehow (perhaps they cancel out if squashed together?). Is there a way to do so?

Answer 1

For those who have this problem and wonder how to work around it without silencing all the errors, here is how I did it in my .vimrc:

au BufWritePre * try | undojoin | Neoformat | catch /^Vim\%((\a\+)\)\=:E790/ | endtry

Credit goes to Christian Brabandt and to this answer from Randy Morris

Answer 2

Using undojoin actually works pretty well:

autocmd BufReadPost *  undojoin | set noexpandtab | retab! 4
autocmd BufWritePre *  undojoin | set expandtab   | retab! 4
autocmd BufWritePost * undojoin | set noexpandtab | retab! 4

However, if you execute :w right after undoing an action, you'll get an error:

Error detected while processing BufWritePre Auto commands for "*":
E790: undojoin is not allowed after undo
Error detected while processing BufWritePost Auto commands for "*":
E790: undojoin is not allowed after undo

---

This error can be silenced using silent! as mentioned in the comments, but may have some unintentional side effects:

autocmd BufReadPost *  silent! undojoin | set noexpandtab | retab! 4
autocmd BufWritePre *  silent! undojoin | set expandtab   | retab! 4
autocmd BufWritePost * silent! undojoin | set noexpandtab | retab! 4

Answer 3

I realize this is an old thread but thought I'd share that I recently discovered :h clear-undo and have found an alternative approach using 'undolevels'. The following example updates a revision date, excluding it from the undo history. Note this happens after the buffer or file is read and not before it is written. The winview lines keep the original cursor position.

function! LastMod()
    let l:winview = winsaveview()

    " from :h clear-undo
    let old_undolevels = &undolevels
    set undolevels=-1
    
    execute "silent!" '%s/\(revised: \)\d\{4}-\d\{2}-\d\{2}/\1'.strftime("%Y-%m-%d")
        
    " from :h clear-undo
    let &undolevels = old_undolevels
    unlet old_undolevels
    
    call winrestview(l:winview)
endfunction

autocmd BufReadPost,FileReadPost * call LastMod()