How to map "make" to "make | copen"?

Question

It would be fine if after :make command vim opened the new buffer with errors and put the cursor to it. Exactly like :make | copen command. How to map sequence :make | copen?

Answer 1

You could create an abbreviation in the command line mode by adding this to your vimrc:

cabbrev mc make<bar>copen

Now when you'll type mc in the command line it will be replaced by make|copen making it faster to type.

You could also create a mapping to invoke the commands you want:

nnoremap <key> :make<bar>copen<CR>

---

EDIT As @Sato Katsura pointed it out in the comment my first version of cabbrev is not a good one: Indeed in the first version mc will be replaced no matter where it is placed in the command line, so for example I you want to search in a buffer for the string mc and you try to hit /mc it will be replaced by /make|copen.

To resolve that @Sato linked an interesting tip. With the following syntax mc will be replaced only if it is the first thing typed in the command line:

cabbrev make <c-r>=(getcmdtype()==':' && getcmdpos()==1 ? 'make<bar>copen' : 'make')<CR>

Answer 2

The best solution is to not create a mapping at all.

Simply put the following snippet in your vimrc:

augroup quickfix
    autocmd!
    " automatic location/quickfix window
    autocmd QuickFixCmdPost [^l]* cwindow
    autocmd QuickFixCmdPost    l* lwindow
augroup END

This will open the quickfix window automatically after :make and other quickfix-related commands like :grep, when there are valid errors (:cwindow versus :copen).

Same for location-related commands like :lvimgrep.

--- EDIT ---

The general structure of an autocommand is:

autocmd [<group>] <EventName>[,<EventName>[,...]] <pattern> <command>

Here, <pattern> is matched against Ex command names:

• l* matches all command names starting with l (:lgrep, :lmake, etc.),
• [^l]* matches all command names not starting with l (:grep, :make, etc.).

Quickfix-related command names start with different letters while location-related command names all start with an l so l as first character is a convenient way to discriminate them.