Fire autocmd FileType on current buffers in windows

Question

Context

I have shortcuts to edit my vimrc and to source my vimrc. When I'm writing code I can quickly add a new mapping and then source vimrc. And all that would be good if I did not use autocmd FileType for most of my mappings.

Since most mappings are specific to one file type I keep my vimrc in a form similar to this:

function! FtPython()
  setlocal expandtab shiftwidth=4 softtabstop=4 autoindent
  nnoremap <buffer> <localleader>c I#<esc>

  " Let's say that this is a new mapping
  nnoremap <buffer> <localleader>cc ^wC:<esc><left>i

endfunction

if has("autocmd")
  augroup filetype_vimrc
    autocmd!
    autocmd FileType python call FtPython()
    ...
endif

Yet, when I add a new mapping to FtPython() and source my vimrc, the new mapping is not present in the python buffers because the FileType event happened long ago, when the file was read.

When I read a buffer back into a window FileType will be fired and the mapping will be added, but that does not happen when a window is already open and I just move into it (Ctrl+W). In essence, once I add a new mapping all currently open windows need to be "kicked" to get the new mapping.

I work around it by doing (I force the FileType event to fire):

set ft=python

But that is quite a lot of typing, sometimes I have 2-3 python files in different windows (split/vsplit) and I need to do it for each. argdo is not an option since it will close the windows (as far as I know).

---

Question

Is there a good way to fire the FileType event on all windows that Vim is currently showing?

Or, maybe, is there a better way to structure the mappings?

Answer 1

Is there a good way to fire the FileType event on all windows that Vim is currently showing?

Use :e instead of :set ft=python to reset the current buffer. It re-reads the file and triggers the relevant autocmds for the buffer.

Update: I missed the part about different files. You could re-set the filetype for all buffers with :bufdo

:bufdo doautocmd FileType

alternatively:

:bufdo let &ft=&ft

There is also doautoall which can re-trigger the FileType autocmd in all buffers:

:doautoall FileType

The methods above are a bit heavy handed and not without drawbacks. If you want to affect only python filetypes:

:bufdo if &ft == 'python' | doautocmd FileType | endif

as a command that accepts the filetype as an argument:

command! -complete=filetype -nargs=1 FiletypeReload bufdo if &ft =~# '\<<args>\>' | doautocmd FileType | endif

Or, maybe, is there a better way to structure the mappings?

You could use filetype scripts in ~/.vim/after/ftplugin/<filetype>.vim. Then you wouldn't need to source vimrc to pick up the changes. The methods above will cause the ftplugin scripts to be sourced for you. Since it's sourced after other filetype scripts, it will also guarantee that the mapped keys are actually yours and not something a plugin introduced.

If you're using this method, you can change the command above to use the filetypeplugin group:

command! -complete=filetype -nargs=1 FiletypeReload bufdo if &ft =~# '\<<args>\>' | doautocmd filetypeplugin FileType | endif

The filetypeplugin group is used to trigger only the FileType autocmd in $VIMRUNTIME/ftplugin.vim which is responsible for running ftplugin scripts. This would be preferred since the outcome is slightly more predictable than triggering FileType autocmds setup at runtime.