Prevent the cursor from moving to the start of the yanked text?

Question

Vim help's change.txt states that

Note that after a characterwise yank command, Vim leaves the cursor on the first yanked character that is closest to the start of the buffer. This means that "yl" doesn't move the cursor, but "yh" moves the cursor one character left.

Rationale:

In Vi the "y" command followed by a backwards motion would sometimes not move the cursor to the first yanked character, because redisplaying was skipped. In Vim it always moves to the first character, as specified by Posix.

With a linewise yank command the cursor is put in the first line, but the column is unmodified, thus it may not be on the first yanked character.

Sure enough, if I have my cursor at V in someVerySpecificSubclass and do a yiw, the cursor will move to the start of the word.

I would like to yank this word without having the cursor move, because a lot of the time I want to change someVerySpecificSubclass to someSubclass but I'll need someVerySpecificSubclass somewhere else in the code.

This movement is not added to the jumplist, so I can't jump back with CTRL-o. I can force adding it to the jumplist with m', so I could m'yiw<C-o>, but that is somewhat long (and I'm not sure how to map it properly).

In any case, it doesn't make sense to me that a yank operation would move the cursor at all.

Related questions:

• Yank a region in VIM without the cursor moving to the top of the block?
• Keep cursor from moving when yanking upwards
• Backward motions in Operator-pending mode move cursor

None of the solutions provided work for my use case, they all seem to assume you want the cursor to be placed at the end of the yanked text, not necessarily at the original position, which can (and in my case is) somehwere in the middle of the yanked text.

Answer 1

Here's some vimscript I whipped up that seems to work pretty well. (disclaimer: I have not done extensive testing on this. I just threw it together in a couple minutes)

function! YankNoMove()
  let repcount = v:count
  if v:count == 0
    let repcount = 1
  endif
  exe "normal! m'".repcount."y".nr2char(getchar())."^O"
endfunction

function! YankObjectNoMove(object)
  let repcount = v:count
  if v:count == 0
    let repcount = 1
  endif
  exe "normal! m'".repcount."y".a:object.nr2char(getchar())."^O"
endfunction

nnoremap <silent> y :<c-u>call YankNoMove()<cr>
nnoremap <silent> yi :<c-u>call YankObjectNoMove('i')<cr>
nnoremap <silent> ya :<c-u>call YankObjectNoMove('a')<cr>

(Note, ^O is the control character <C-o> and I typed it with <C-v><C-o>)

This works the way you thought of, but neatly wraps it up in a vimscript function. It works with counts, but only if the count is before the yank. For example, 2yw works, but y2w does not. This will also only work with basic motions like yb, yw, yiw, etc. It will not work with y/foo or yfn, and unfortunately, it also breaks them. You could get around this by doing

nnoremap yf yf
nnoremap yF yF
nnoremap yt yt
nnoremap yT yT
nnoremap y/ y/
nnoremap y? y?

Although this is not the ideal solution. Probably the easier way would just be to treat YankNoMove as an alternate operator, separate from y and do

nnoremap <silent> <leader>y :<c-u>call YankNoMove()<cr>
nnoremap <silent> <leader>yi :<c-u>call YankObjectNoMove('i')<cr>
nnoremap <silent> <leader>ya :<c-u>call YankObjectNoMove('a')<cr>

Obviously, you can choose your own key sequence if you do not like <leader>y

Answer 2

You could also do it this way:

vnoremap <A-c> ygv<Esc>a
xnoremap <A-c> ygv<Esc>a
snoremap <A-c> ygv<Esc>a

y gv <Esc> a
^  ^   ^   ^
|  |   |   |____ go back to insert mode (if you wanted to quickly edit)
|  |   |      
|  |   |________ get out of visual/selection mode      
|  |         
|  |____________ select previous selection         
|           
|_______________ yank (copy)           

Answer 3

Native vim solution Update:

Source: https://vi.stackexchange.com/a/38180/7339

augroup yank_restore_cursor
    autocmd!
    autocmd VimEnter,CursorMoved *
        \ let s:cursor = getpos('.')
    autocmd TextYankPost *
        \ if v:event.operator ==? 'y' |
            \ call setpos('.', s:cursor) |
        \ endif
augroup END

Using the Preserve function

if !exists('*Preserve')
    function! Preserve(command)
        try
            let l:win_view = winsaveview()
             "silent! keepjumps keeppatterns execute a:command
            silent! execute 'keeppatterns keepjumps ' . a:command
        finally
            call winrestview(l:win_view)
        endtry
    endfunction
endif

Copy a paragraph whithout moving the cursor

:call Preserve('normal yap')

If we could wrap this idea in a more generic solution would be gret

Answer 4

I have come up with a simpler solution using autocmd event TextYankPost, it works fine for me:

nnoremap y myy

augroup restore_after_yank
  autocmd!
  autocmd TextYankPost * silent! normal `y
augroup END

my will set a mark y to current cursor poistion. In the autocmd, we restore the cursor position using `y.