How can you indent your current file without losing your cursor position?

Question

I was reading that the way to indent in vim is a gg=G sequence. This however loses my cursor position.

How can I indent my file without losing my cursor position?

Answer 1

You could define a custom command using :help winsaveview():

command! -range=% Equal let b:wv = winsaveview() | silent execute <line1> . ',' . <line2> . 'normal! ==' | call winrestview(b:wv)

:Equal             like gg=G
:12,23Equal        like :12,23normal! ==
v{motion}:Equal    like v{motion}=

Answer 2

Expanding on Karl Yngve Lervåg's answer:

maHmbgg=G`bzt`a

Explanation:

ma   - Set mark 'a'
H    - Jump to the top of the window
mb   - Set mark 'b'
gg=G - Indent from the first line to the last
`b   - Jump to mark 'b'
zt   - Scroll the cursor line to the top of the window
`a   - Jump to mark 'a'

This will preserve your scroll position after indenting.

If you want to preserve the relative cursor position after the cursor line has been indented, you have to update the new cursor position after indenting. The following script expands on romainl's answer:

function! s:reindent(line1, line2)
  let view = winsaveview()
  let text = getline('.')
  execute a:line1.','.a:line2.'normal! =='
  let view.col -= strchars(text) - strchars(getline(view.lnum))
  call winrestview(view)
endfunction


command! -range=% Reindent call s:reindent(<line1>, <line2>)

Answer 3

You should use a mark, e.g.:

magg=G`a

Here ma will set the a mark at the current position, then gg=G indents the file, and `a will jump to the mark.

In order to put the cursor at the center of the screen afterwards, you could finish this off with zz. See :h scroll-cursor for more info and for similar scroll mappings.