How do I get the next n characters input by the user?

Question

I answered a question that needed a user input using the built-in input() function, which works great.

I was wondering if it was possible to ask vim for (let say) the next 3 characters input, without having to use the input function, and without having to press CR to confirm.

So far I have not found anything in the documentation for this.

Any idea?

Answer 1

Thanks to VanLaser comment, here is a little function to achieve what I wanted:

function! GetNChar()
  let l:number = 3
  let l:string = ""

  while l:number > 0
    let l:string .= nr2char(getchar())
    let l:number -= 1
  endwhile

  echo l:string
endfunction

nnoremap gs :call GetNChar()<CR>

Here I append the chars into a string and display it, but one could do whatever he wants with it.

Answer 2

Here's the solution from nobe4 slightly improved:

function! InputNChars(number_of_chars, prompt)
    echo a:prompt
    let l:number = a:number_of_chars
    let l:result = ""
    while l:number > 0
        let l:input = nr2char(getchar())
        let l:result .= l:input
        let l:number -= 1
        echon l:input
    endwhile
    return l:result
endfunction