How to use <Leader> in a normal command?

Question

In the command-line mode or in a vimscript I can use the following to duplicate a line:

normal! Yp

Now let's says that I map my leader key to do that: nnoremap <Leader>a Yp. If I use this key combination the following command will interpret litterally the characters or <leader>:

normal! <Leader>a

How can I use a key combination including <leader> in a normal command?

Note that other keys like <Right> or <F3> doesn't work neither.

Edit Some side notes:

• Using normal or normal! doesn't seem to change something to the problem
• The point of the question is to be able to use <Leader> and not replace it by its value for two 2 reasons:
  • It is more portable if I use it in a script and want to distribute it.
  • My leader is <Space> so even if I replace <Leader> by its value I still have the same problem. (Note that I could maybe escape a space character but that is not the point of the question)

Answer 1

I made up a solution to extract the leader, handle the special <space> case and execute the normal command.

The space is a special case, because the normal command does not accept expressions starting with a space:

:h normal

{commands} cannot start with a space.  Put a count of
1 (one) before it, "1 " is one space.

Here is the function and command:

function! ExecuteLeader(suffix)
  let l:leader = get(g:,"mapleader","\\")

  if l:leader == ' '
    let l:leader = '1' . l:leader
  endif

  execute "normal ".l:leader.a:suffix
endfunction

command! -nargs=1 NormLead call ExecuteLeader(<f-args>)

You can use it this way:

:NormLead a
-> will execute `normal <leader>a`

---

(Thanks @statox for the update): If you want a one-liner command, without function, you can use the following:

command! -nargs=1 NormLead  let leader=get(g:,"mapleader","\\") | exec "normal " . (leader==' '?"1":leader).<f-args>

---

This is just for the leader key, but if you want to extend to any kind of key I think you need to use execute anyway.

In the normal help:

An alternative is to use :execute, which uses a
expression as argument.  This allows the use of
printable characters to represent special characters.

Example:
    :exe "normal \<c-w>\<c-w>"
{not in Vi, of course}