How can I stop Vim from writing a file without throwing an error?

Question

I'm trying to improve the code from this answer to ask for confirmation before creating the missing directory, this is what I write:

function! CreateDirectoryAskConfirmation(path)
    if !isdirectory(a:path)
        echohl Question
        echo "Create directory " . a:path . "?"
        echohl None

        let response = nr2char(getchar())
        if response ==? "y"
            call mkdir(a:path, "p")
        endif
    endif
endfunction

autocmd BufWritePre * call CreateDirectoryAskConfirmation(expand("<afile>:p:h"))

One thing I'm missing: when I don't press y at the prompt I'd like Vim to abort the write so I don't get the error E212: Can't open file for writing and I don't need to hit another key to make the error message disappear. There is a way to achieve this?

Answer 1

Instead of using the BufWritePre autocmd, you can use the BufWriteCmd autocmd, from :help BufWriteCmd:

Should do the writing of the file and reset 'modified' if successful, unless '+' is in 'cpo' and writing to another file cpo-+.

We can just call :write from the autocmd. This will take care of setting modified.

So the logic would then be modified to call :write when the directory already exist, and call :write after creating the directory if it doesn't exist yet. If you press n, we do nothing. This will leave the buffer as-is, and won't re-set modified, so :q will still give you a E37: No write since last change error.

function! CreateDirectoryAskConfirmation(path, dir)
    silent doautocmd BufWritePre

    " Directory exists, :write and return
    if isdirectory(a:dir)
        execute 'write ' . a:path
        silent doautocmd BufWritePost
        return
    endif

    " Ask for confirmation to create this directory
    echohl Question
    echo "Create directory `" . a:dir . "' [y/N]?"
    echohl None

    let response = nr2char(getchar())
    " mkdir() and :write if we want to make a directory
    if response ==? "y"
        call mkdir(a:dir, "p")
        execute 'write ' . a:path
        silent doautocmd BufWritePost
    endif
endfunction

autocmd BufWriteCmd * call CreateDirectoryAskConfirmation(expand("<amatch>:p"), expand("<amatch>:p:h"))