Have different tabs/windows remembering their mode

Question

I have done a bit of research about this but found only very old answers, like this one, and all on the negative side.

My problem is the following --- suppose you are working on a document/program, say for example a LaTeX file. You have some error and you open another window/tab with the log file, which is opened in read-only mode (the same for the quickfix window).

Then you switch to insert mode in your main file, and all the windows/tabs/buffers enters insert mode. So I can't switch rapidly to the "log" windows/tab to scroll/move/hitting "q" to close it, because it's in input mode...

So the question is — is it possible to remember the mode at a window/tab level?

I understand that it could have been confusing in the original vi, but with things like airline and colors it's quite handy to know the mode in which you are...

Answer 1

In order for Vim to remember if you are in insert mode or not for each window opened, you could add the following autocmds inside your vimrc:

augroup RememberMode
    autocmd!
    autocmd WinLeave * let w:mode_state = mode()
    autocmd WinEnter *
                \ if exists('w:mode_state') && w:mode_state ==# 'i' |
                \     startinsert |
                \ elseif exists('w:mode_state') && mode() ==# 'i' |
                \     stopinsert |
                \ endif
augroup END

The first one autocmd WinLeave * let w:mode_state = mode() stores the mode in which you are when you leave a window (WinLeave event) inside the window-local variable w:mode_state (you can change the name of the variable if you don't like it, but keep the window-local scope w:).

The second one tests, when you enter a window (WinEnter event), whether the window-local variable w:mode_state exists (because if it's a window you just created, it will not exist and the following test would probably raise an error), and if its value is 'i'.
If it is, it means that the last time you left this window you were in insert mode, so Vim puts you back in insert mode with the Ex command :startinsert.

Otherwise, the autocmd tests whether w:mode_state exists and you're in insert mode. In this case, it means that you were already in this window in the past (otherwise the variable wouldn't exist), but you were not in insert mode (because this case has already been covered), you were in another mode. So Vim makes you quit insert mode with the Ex command :stopinsert.

---

For more information, see:

:help :augroup
:help :autocmd
:help WinLeave
:help WinEnter
:help w:
:help mode()
:help exists()
:help :startinsert
:help :stopinsert

Answer 2

I'm going to be bold and claim that your problem will be solved if you learn to use Vim/vi without using the mouse. Learn to stay in normal mode on a default basis, from which changing the window can be done with <c-w><c-w>. You will be happier in the long term, even though this may take some effort and time in the short term.

Note: I know this is not an answer to your actual question, and I'll accept being downvoted for that reason.