How do I add skeleton text to new vim files?

Question

I use Vim for writing C++, and I have quite a few #include<> statements, comments, etc. that I must include in each new file I create. I've added

autocmd BufNewFile *.cpp r C:\(full file path of skeleton text file) 

to my vimrc, because I heard this creates a buffer with the text I need in it. How do I go about adding this text to a new file? Is there an easy way to do this from the buffer, or is there another easy way to go about doing this? I've also heard a little about template plugins. Is there a very simple one that could do this for me?

Answer 1

Skeleton text from an existing file can be added to a new file by inserting the line

autocmd BufNewFile *.cpp r C:\(full file path of skeleton text file)

into the vimrc. The BufNewFile event does not work if the new file is created in two steps using :enew then :sav filename. Instead, creating a new file using :e filename triggers the BufNewFile event's autocommand in the vimrc, adding the contents of the skeleton text file to the newly created file.

Answer 2

Indeed, template expander plugins will help you in this task. :read is the step 0 of template expander plugins.

For instance, mu-template will try to include foo.h from foo.cpp if foo.h is detected. It'll also permit to expand headers with dynamic data within them (date, author, license/copyright, etc).

Answer 3

To setup default skeleton for all filetypes and customize it for specific project:

function! s:load_skeleton(type)
  " do nothing if no filetype
  if empty(a:type) | return | endif

  " glob every directory of rtp to search for skeleton/filetype
  let skeletons = globpath(&rtp, 'skeleton/' . a:type, 0, 1)
  if empty(skeletons) | return | endif

  " read last skeleton into 1st line.
  exe '0read ' . skeletons[-1]
endfunction

augroup aug_skeleton
  au!

  " BufNewFile event is trigged when you edit a new file.
  autocmd BufNewFile * call s:load_skeleton(&filetype)
augroup end

Put default skeletons under ~/.vim/skeleton, eg: ~/.vim/skeleton/vim, ~/.vim/skeleton/sh.

Put project specific skeleton under balabala/project/.vim/skeleton. As long as ~/.vim appears before balabala/project/.vim in :h rtp, balabala/project/skeleton/ will be used as skeleton directory.