How to execute a string of conditional commands which includes a shell command?

Question

I currently have the following auto-command (in my vimrc) -

autocmd BufEnter *.c nmap <F5> :Makexec<CR> 
  \:if findfile( expand("%:p:r").".exe" ,expand("%:p:h") ) != ""<CR>
  \    :!%:p:r.exe<CR>
  \:else<CR>
  \    :vert topleft cwin<CR>
  \    :vert resize 50<CR>
  \:endif<CR> 

What is Makexec?
Not relevant in my opinion, however if necessary see below *

I want to convert this auto-command such that it executes a single string where the string contains the above commands chained together.

• Attempt 1

  let g:c_exe_str="Makexec | if findfile(expand(\"%:p:r\").\".exe\", expand(\"%:p:h\")) != \"\" | !%:p:r.exe | else | vert topleft cwin | vert resize 50 | endif"
  
  autocmd BufEnter *.c nmap <F5> :execute g:c_exe_str<CR>
  

  This didn't work as I had expected, I get the following error at the shell -

  C:\windows\system32\cmd.exe /c D:\NewFolder\c_experiments.exe | else | vert topleft cwin | vert resize 50 | endif
  'else' is not recognized as an internal or external command, operable program or batch file.

• Attempt 2

  let g:c_exe_str="Makexec | if findfile(expand(\"%:p:r\").\".exe\", expand(\"%:p:h\")) != \"\" | echo system(expand(\"%:p:r\").\".exe\") | else | vert topleft cwin | vert resize 50 | endif"
  
  autocmd BufEnter *.c nmap <F5> :execute g:c_exe_str<CR>
  

  This kinda (sic) works but without displaying the executable's output in a shell window; basically it doesn't work the same way as the original auto-command.

How do I go about exactly mimicking the original auto-command's steps using execute()?

* command -nargs=? Makexec :w | :silent exe "!rm -f %:p:r.exe" | :let &makeprg='gcc -Wall -Werror -o %< % <args>' | :make!

Answer 1

It looks like the end goal is simply to have your F5 be mapped to certain functionality when you are in a C source file.

Presuming you already have file type detection switched on (:help filetype), the way I would achieve this is to:

1. Create a function to run the code,
2. Create a mapping to call the function when F5 is pressed,

3. Place the code for both of these in the file ~/.vim/after/ftplugin/c.vim, which will cause the mapping to be created whenever a file of type C is edited. (See :help ftplugin-overrule for more details.)

   function! s:f5()
     Makexec 
     if findfile( expand("%:p:r").".exe" ,expand("%:p:h") ) != ""
       !%:p:r.exe
     else
       vert topleft cwin
       vert resize 50
     endif
   endfunction
   
   nnoremap <buffer> <silent> <F5> :call <SID>f5()<CR>
   

N.B.

1. The s: and <SID> prefixes to the function name mean that the function is only defined within that script, preventing it from clashing with similarly named functions elsewhere, (:help <SID>)
2. <buffer> causes the mapping only to apply to the individual buffer, so if you switch to a file with a different filetype, the F5 key won't erroneously call the function,
3. <silent> just means that the mapping contents (:call...) won't be echoed to the screen when the mapping is invoked,

4. If you don't have file type detection switched on, and for some reason you don't want to switch it on, you could of course use an autocommand to create the mapping, similar to what you had before:

   autocmd BufEnter *.c nnoremap <buffer> <silent> <F5> :call <SID>f5()<CR>