Is there a way to conceal across lines?

Question

Here is my use case:

I have lots of code which because of style enforcement we write newlines after and before each open and close brace (respectively).

Example:

function func(args) {

    statement 1;
    statement 2;

    if (condition) {

        statement 3; 

    }

}

While this is nice and easy to read, I do consider this to be a expletive-worthy waste of space, but my teammates do not agree with me. Basically this is how we're checking in our code and that's that.

I was thinking that maybe I can use Vim features to help me save screen real-estate, while still allowing me to write the code in the verbose way. I don't mind typing it out, I just want more efficient use of space. I figured maybe I can have Vim auto-collapse the gratuitous empty lines.

I am finding it somewhat challenging to set this up using syntax rules because whatever I write seems to conflict with existing syntax rules, but what I decided to do as a first attempt was to write these rules which will not collide:

syntax match aaaaaaaaa "\vabcd" conceal cchar=A
syntax match bbbbbbbbb "\vef\ngh" conceal cchar=B

The second rule here is close to what I want, which for the open bracket case is something like /\v\{(\n\s*){2,}: match an open-bracket with any number greater than or equal to 2 of a newline followed by only whitespace.

What happens inside of vim however is the following:

1. If I type abcd in a line, it gets concealed to A as expected.

2. If I type ef on one line and gh on the next, BOTH lines become concealed with B.

I was really really hoping the two lines ef\ngh would have been concealed into a single line so that I can save some vertical buffer space this way.

But I see now that it's probably a Vim implementation detail problem. Collapsing lines is a problem for code folding to solve, probably just out of scope as far as conceal is concerned.

So I wonder if there is still some way to do what I want to do. Maybe using fold markers somehow? The problem is that I need to fold only the empty whitespace.

Answer 1

It is possible to abuse folds to hide extra empty lines. Here is how one could do it:

function! SkipNewlineFoldExpr()
    let l:curline = getline(v:lnum)
    " fold begins at {$ or one line before }$
    if l:curline[-1:] == '{' || getline(v:lnum + 1)[-1:] == '}'
        return '>1'
    endif
    " fold ends one line after {$ or at }$
    if getline(v:lnum - 1)[-1:] == '{' || l:curline[-1:] == '}'
        return '<1'
    endif
    return 0
endfunction

function! SkipNewlineFoldText()
    " fold text matches non-empty line
    return getline(getline(v:foldstart)[-1:] == '{' ? v:foldstart : v:foldend)
endfunction

" customize how fold is defined
set foldexpr=SkipNewlineFoldExpr()
" customize how fold looks like
set foldtext=SkipNewlineFoldText()
" use 'foldexpr'
set foldmethod=expr

" Optional:
" drop highlighting of folds
" highlight clear Folded
" automatically close folds
" set foldclose=all
" automatically open folds on any actions on folded lines
" set foldopen=all

It would look something like this:

As you can see there is no syntax highlighting on folded lines, still might be something more bearable than lots of unnecessary empty lines. You can also switch folds on and off with zi shortcut in case they are getting in your way.

Folds aren't a small topic and Vim has a separate help file on them. Related options are linked there too.

Detailed behaviour of cursor and search can be controlled via 'foldopen', which combined with 'foldclose' defines when folds will be automatically opened and closed for you.

Answer 2

First off, that's a shitty style enforcement and you have my sympathies. Instead of hiding how about creating a mapping or functions (like shown below) for deleting the unnecessary lines before editing and adding them when you're done ? something along the lines:

function! Clean()
    %s/{\n^$/{/
    %s/^$\n\(\s*}\)/\1/
endfunction

function! Pollute()
    %s/{$/{\r/
    %s/\(\s*}\)/\r\1/
endfunction

The basic idea begin, delete the empty lines at read and replace them at write, didn't try it but I feel like this can be added as an autocmd like so:

au BufReadPost *.cpp call Clean()
au BufWritePost *.cpp call Pollute()