How can I test the result of execute saveas?

Question

I have a function that renames a file by saving it to the new location then deleting the old:

execute "saveas" fnameescape(l:new_path)
call delete(l:old_path)

I ran into a problem with this today. l:new_path already existed on disk, and I didn't want to overwrite it, so I answered "No" when prompted, but the function proceeded to delete l:old_path anyways.

How can I test the execute "saveas" command and prevent the delete in this case? I want to say something like:

execute "saveas" fnameescape(l:new_path) || return

But this throws an error: E121: Undefined variable: return.

In the shell I could test $?. Does VimL have something similar?

Answer 1

Following the suggestion of @filbranden you could do:

function! Rename(old_path, new_path) abort
  let c=&confirm
  set noconfirm
  try
    execute "saveas" fnameescape(a:new_path)
  catch /File exists/
    echo 'fail to rename to: ' . fnameescape(a:new_path)
    return
  finally
    let &confirm = c
  endtry
  call delete(a:old_path)
endfunction

Remark: I propose to temporarily disable the noconfirm option such that the exception is raised.

Answer 2

Here is a simple implementation:

function! Rename(old_path, new_path)
    let old_filename = fnameescape(a:old_path)
    let new_filename = fnameescape(a:new_path)

    if glob(new_filename)->empty()
        execute "saveas " .. new_filename
        call delete(old_filename)
    else
        echohl WarningMsg
        echo new_filename .. " already exists"
        echohl None
    endif
endfunction

Where we use :help glob() to determine if new_filename exists:

• If it does,
  • glob() returns its full path,
    • empty() is false,
      • we can't proceed.
• If it doesn't,
  • glob() returns an empty string,
    • empty() is true,
      • we can proceed.

But that is all just a fancy way to reinvent :help rename().