Highlighted undo in Vim

Question

I'm trying to have a highlighted undo in Vim, like spacemacs default config. Sometimes when I want quick undo's, I can't realize what changed because it's instantaneous. So I am trying to have something like this when a press undo:

Anyone have an idea how to do this in Vim?

(I already have Gundo plugin, i just want to make the default undo more smooth)

Edit: The undotree plugin does the work (Gundo doesn't highlight the changes), just use the UndotreeToggle command and all future changes on the file will be highlighted.

Answer 1

New solution

You can view your last changes with the :changes command. So you can fecth your most recent line change with a regex and then apply the line to matchadd() as suggested by @joeytwiddle.

Here is the code :

function! DiffWithPrevious()
  call clearmatches()
  redir => message
  silent changes
  redir END
  let line = matchstr(message, '\v\n\s{4}1[^0-9]*\zs\d+\ze')
  highlight TemporalDiff ctermbg=green guibg=green
  let m = matchadd('TemporalDiff', '\%'.line.'l')
endfunction

Note :

• This function only add a new highlight without removing the old one, so you'd have to remove the old one first. With the clearmatches function you can remove the matches before adding a new one. Careful, it will remove ALL matches. If you want more granularity, you can save your match and remove it manually :

e.g.

function! DiffWithPrevious()
  call matchdelete(m)
  ... 
  let m = matchadd('TemporalDiff', '\%'.line.'l')
endfunction

• After some tests, I found out it only works for one-line change.

References :

• Why is \r a newline for Vim?
• regex in vimscript
• http://vim.wikia.com/wiki/Capture_ex_command_output
• http://vim.wikia.com/wiki/Highlight_long_lines

---

Old solution

Here is a possible solution, mainly inspired by Diff current buffer and the original file :

function! DiffWithPrevious()
  undo
  write
  redo
  let filetype=&ft
  diffthis
  vnew | r # | normal! 1Gdd
  diffthis
  exe "setlocal bt=nofile bh=wipe nobl noswf ro ft=" . filetype
endfunction

The idea is to diff the file with the file on the system, so you undo your last change, write it, redo the las change and execute the diff.

I think this should do the job for time-to-time temporal diff visualisations.

Answer 2

Check my changes plugin and be sure to set the variable g:changes_linehi_diff to 1

Answer 3

For someone who is trying the same of me, that is closest that i reached thanks to the answers.

function! DiffWithPrevious()
  call clearmatches()
  undo
  redir => message
  silent changes
  redir END
  let line = matchstr(message, '\v\n\s{4}1[^0-9]*\zs\d+\ze')
  highlight TemporalDiff ctermbg=black guibg=black
  let m = matchadd('TemporalDiff', '\%'.line.'l')
  redraw
  let gchar = getchar()
  highlight TemporalDiff ctermbg=none guibg=none
  let m = matchadd('TemporalDiff', '\%'.line.'l')
endfunction