Switch focus to :terminal buffer

Question

I am trying to recreate the functionality of the very old conque plugin via terminal in modern vim. So far I have found a few plugins that send code to a terminal buffer. However, these do not update the display in the terminal buffer (and does not match conque's behaviour). What I want is a way to script the following:

1. call term_sendkeys to send some code to the terminal buffer. (existing plugins already do this).
2. change focus to the terminal buffer so that the sent code renders in that window. (this part I do not know how to do.)

Any hints? I believe I can get the job number of the terminal buffer from term_getjob, but then I am at a loss.

Answer 1

I would do:

function! MoveFocusToTerminal()
  let loop = 0
  let term_buffers = term_list()
  while 1
    let loop = loop + 1
    let bufnr = bufnr('%')
    if loop > 10
      " Don't search for more than 10 windows
      " To handle the case where there are no terminal window
      break
    endif
    if index(term_buffers, bufnr) >= 0
      " Stop if the corresponding buffer is a terminal buffer
      break
    endif
    " Go to the next window
    wincmd w
  endwhile
endfunction

Answer 2

I might misunderstand the question, but you can simply switch to a particular window using the normal window-move commands.

So if your terminal is in the second window (starting from top to bottom and left to right), simply pressing CTRL-W 2 w should move your cursor directly there.

You can also script it like this:

exe term_list()[0]->bufwinnr() .. 'wincmd w'

This assumes that you have at least one terminal window open.

Answer 3

Building on the previous answers I would do:

function! TerminalFocus()
    let l:term_bufs = term_list()
    if len(term_bufs) > 0 && len(win_findbuf(term_bufs[0])) > 0
        return ':' . win_id2win(win_findbuf(term_bufs[0])[0]) . 'wincmd w' . "\<CR>"
    endif
    return
endfunction

nnoremap <expr> <YOUR_MAPPING> TerminalFocus()

This function first fetches current terminal processes and then checks if there any. Then move to the window by converting the bufnr from the first element in term_list() to a window id by win_findbuf() and converting this window id to a window by win_id2win(). This will always move the focus to the first terminal in term_list(). Then the function is called via a mapping, if you so wish.