change behaviour of > / < and >> / << to insert / remove only leading tabs

Question

i want > / < and >> / << to simply insert and remove tab characters at the beginning of the line.

variant: i would even prefer to have> / < and >>/ << insert / remove a tab character at the position of the last tab character of each line within the selection (defaulting to the first character of each line within the selection whenever none such tab character is found).

can i change their behaviour to do so?

example. denoting tabs as ›––– and spaces as ·, say i have some text like the following.

›–––··A
›–––······B
›–––····C

i have preserveindent set. selecting all three lines in visual mode and pressing > thus far yields the following.

›–––··›–··A
›–––······›–··B
›–––····›–––C

clearly i want it to be as follows.

›–––›–––··A
›–––›–––······B
›–––›–––····C

variant. the variant allows to indent in a more reasonable way some text with a preceding comment # … like the following.

›–––··A
›–––······B
#›––····C

indenting the three lines by pressing > is then supposed to yield the following.

›–––›–––··A
›–––›–––······B
#›––›–––····C

context. it appears that vim/neovim does something way more complicated, namely to compute the indentation level of each line by counting its leading tabs and spaces, then increase / decrease this indentation level and finally indent the entire line fully anew by inserting a number of first tabs, then spaces corresponding to the freshly increased / decreased indentation level.

so this messes up the indentation structure when using “tabs for indentation, spaces for alignment”.

if preserveindent is on, it seems that indentation is increased / decreased by inserting a mixture of first spaces, then tabs right before the first non-white-space character, which is again way more complicated than what i want.

i want this for a sane configuration for using tabs as indentation, spaces as alignment; this is a follow-up to a previous question about leading tabs.

Answer 1

Here's the code that does the job (only > and <, but you can easily add >> or <<). Assuming you have preserveindent set, it works in visual mode, as well as range motions e.g. >2j or <}.

function! DoIndent(type, ...)
  if a:0
    " visual mode
    exec "sil! keepp '<,'>s/^/" . repeat("\t", v:count1) . "/"
  else
    " normal mode (followed by a motion)
    exec "sil! keepp '[,']s/^/\t/"
  endif
endfunction
function! DoDedent(type, ...)
  if a:0
    " visual mode
    exec "sil! keepp '<,'>s/^\t\\{," . v:count1 . "}//"
  else
    " normal mode (followed by a motion)
    exec "sil! keepp '[,']s/^\t//"
  endif
endfunction

nnoremap <silent> > :set opfunc=DoIndent<CR>g@
vnoremap <silent> > :<C-U>call DoIndent(visualmode(), 1)<CR>
nnoremap <silent> < :set opfunc=DoDedent<CR>g@
vnoremap <silent> < :<C-U>call DoDedent(visualmode(), 1)<CR>

The basic idea is: to insert a leading \t, replace start-of-line i.e. ^ with a \t; to remove one, replace ^\t with nothing. So we map > and < to perform such substitutions.

Since substitution is not affected by preserveindent, we end just just inserting/deleting one tab, without any extra spaces.

For example, the "sil! keepp '<,'>s/^/\t/" breaks down to

1. sil! supress messages from :s
2. keepp keep the search pattern (@/) unchanged because normally :s clobbers it
3. '<,'> let the substitution work on visually selected lines. Similarly, '[,'] means the lines covered by a motion like 2j or }.
4. s/^/\t/ substitute start-of-line with a tab, essentially adding a leading tab

update: Use repeat and the \{ regex to perform multiple shifts in visual mode e.g. in visual mode, 2< dedents each line of the selection by up to two \t's.