How to close Terminal and NERDTree windows if they are the last windows?

Question

If I close all buffers, I'm left with the terminal window, which automatically opens whenever I open Vim.

I would like it close automatically when I exit Vim.

I see that on the NERDTree repo, they included a code that will automatically close NERDTree if it is the last window:

" Exit Vim if NERDTree is the only window remaining in the only tab.
autocmd BufEnter * if tabpagenr('$') == 1 && winnr('$') == 1 && exists('b:NERDTree') && b:NERDTree.isTabTree() | quit | endif

I want similarly that: if the terminal window is the last window, Vim close it automatically.

Edit: If the terminal window and NERDTree are the last windows, I want them both to close automatically.

Because I do not want to quit them manually every time I finish editing. In addition, I have the following code for NERDTree in my vimrc:

" Exit Vim if NERDTree is the only window remaining in the only tab.
autocmd BufEnter * if tabpagenr('$') == 1 && winnr('$') == 1 && exists('b:NERDTree') && b:NERDTree.isTabTree() | quit | endif

" Close the tab if NERDTree is the only window remaining in it.
autocmd BufEnter * if winnr('$') == 1 && exists('b:NERDTree') && b:NERDTree.isTabTree() | quit | endif

Answer 1

Here is a more sophisticated solution.

It try to close Vim if the only visible windows are 'side bars' (buffer that don't contains 'real' document) like:

• Terminal
• QuickFix window
• LocationList window
• Help window
• NERDTree side bar
• UndoTree side bar
• Read Only buffers

function! IsSideBar(buf_nr)
  " Returns 1 if the buffer is actual a side bar
  " - A terminal
  " - The NERDTree side bar
  " - The QuickFix window
  " - The Help window
  " - The UndoTree side bar
  " - ...
  let buf_name = bufname(a:buf_nr)
  let buf_type = getbufvar(a:buf_nr, '&filetype')
  let readonly = getbufvar(a:buf_nr, '&readonly')

  let term_buffers = term_list()

  if readonly
    return 1

  elseif buf_type ==# 'qf'
    " QuickFix, LocationList:
    " Not Read Only
    return 1

  elseif buf_type ==# 'help'
    " Read Only
    " Help Window:
    return 1

  elseif buf_type ==# 'undotree'
    " Not Read Only
    return 1

  elseif buf_type ==# 'nerdtree'
    " Read Only
    return 1

  elseif index(term_buffers, a:buf_nr) >= 0
    return 1

  else
    return 0

  endif
endfunction

function! GetNumWindows()
  " Returns the number of window that are not side bars
  let num_windows = 0
  for win_nr in range(1, winnr('$'))
    let buf_nr = winbufnr(win_nr)

    if IsSideBar(buf_nr)
      continue
    endif

    let num_windows = num_windows + 1
  endfor

  return num_windows
endfunction

function! KillSideBars()
  let num_windows = GetNumWindows()
  if num_windows > 0
    " If there are some non side bar windows do nothing:
    return
  endif

  " Delete the terminal buffers that don't correspond to a window
  let term_buffers = term_list()
  for buf_nr in term_buffers
    if len(win_findbuf(buf_nr)) == 0
      " Exit terminal not associated to a window
      execute 'bd! ' . buf_nr
    endif
  endfor

  let term_buffers = term_list()
  let buf_nr = bufnr('%')
  if index(term_buffers, buf_nr) >= 0
    " Kill the terminal buffer and quit
    call feedkeys("\<C-w>:bd!\<CR>:quit\<CR>:\<BS>")
  else
    " Kill the side bar window
    call feedkeys(":quit\<CR>:\<BS>")
  endif
endfunction

autocmd BufEnter * call KillSideBars()

Answer 2

I would do:

autocmd BufEnter * if tabpagenr('$') == 1 && winnr('$') == 1 && &buftype ==# 'terminal' | bd! | q | endif

Compare to the NerdTree solution we do:

• Check that the last buffer is a terminal buffer (&buftype ==# 'terminal')
• Force to delete that buffer even it has been modified (bd!)