Multiple search-replace operations on a selection

Question

I have a LaTeX file with a bunch of commands of the form \label{<word>} where the <word> represents a string that contains special characters, namely á é í ó ú ý ð þ æ ö. I'm looking for a quick way to change the special characters into a corresponding ASCII character(s): a e i o u y dh th ae oe. To give an example, I want to change \label{orðabók} to \label{ordhabok}.

If I wanted just to change, for example, all þ's to th, I would visually select the word inside the \label{}, exit to normal mode and then use

:s/\%Vþ/th/ge

And I could give two such commands at the same time using |, e.g.

:s/\%Vþ/th/ge|s/\%Vð/dh/ge

I guess I could just string together all ten commands, but I was hoping for a more elegant way. In particular, I would like to not have to write the \%V and the g every time.

A follow-up question: I have to do this for every \label{} command in a very long file, and I plan to make a macro or commmand that automates it. My plan was to make a macro that searches for the next occurance of \label{, visually selects the word inside the {}, and performs the substitutions I described above. Then I would just count the \label commands and run the macro that many times. If I get help with the first question, then I know how to implement this. But is there another method that would be faster for a very long file?

Answer 1

How about ... a substitution inside another one, and all thrown in a loop? E.g.

function! s:replaceSpecialChars(name)
    let from = ['á','é','í','ó','ú','ý','ð','þ','æ','ö']
    let to = ['a','e','i','o','u','y','dh','th','ae','oe']

    let i = 0
    while i < len(from)
        exe '%s/' . a:name . '{\zs.\{-}\ze}/\=substitute(submatch(0),from[i], to[i], "g")/g'
        let i += 1
    endwhile
endfunction

command! -nargs=1 ReplaceSpecialChars call s:replaceSpecialChars(<f-args>)

---

Copy the above code in a vim file, and source the file (e.g. :w and so % if it's the current file). Then you can run it when you are in your LaTeX buffer like this:

:ReplaceSpecialChars label

Just make sure to keep those lists (from, to) matched (equal nr. of elements).

This function globally replaces, in turn, any number of occurences of one of the characters from the from[] list to their to[] correspondent, but only for text found inside the <name>{ } construct.

Answer 2

Tim Pope's abolish.vim plugin provides a :Subvert (:S for short) command that lets you substitute a list of things for another list of things. For example, the following command will change a to x, b to y, and c to z:

:S/{a,b,c}/{x,y,z}/g

The plugin also provides a lot of other cool functionality that can't be easily articulated; I recommend checking it out.

Answer 3

How about that.

1. define your substitution dictionary:

   :let dict_subst = { 
        \ 'á': 'a', 
        \ 'é': 'e', 
        \ 'í': 'i', 
        \ 'ó': 'o', 
        \ 'ú': 'u', 
        \ 'ý': 'y', 
        \ 'ð': 'dh', 
        \ 'þ': 'th', 
        \ 'æ': 'ae', 
        \ 'ö': 'oe'} 
   

2. Then call your substitution function like this:

   :exe ":s/".join(keys(dict_subst),'\|').'/\=dict_subst[submatch(0)]/g'