Autocmd and key mapping with a conditional expression

Question

I am currently running the following configuration for latex: NVim 0.9, Vmitex and Evince.

I have been trying to map a key to open <current-file>.log, while the current-file is a name taken from a currently opened file without extension, e.g. from something.tex.

Here is my first attempt:

autocmd FileType tex nmap <buffer> <F5> :view \| split %:p:r.log<CR>

while it works it also creates multiple issues. Essentially the *.log can be recreated, deleted by external process latexmk, not existing etc. For instance, if the file was opened by nvim, then closed but later the file was cleared by external process, nvim would warn about it but would also bring the old version of the file, probably from a swap.

Therefore, I'd rather check if the file exists before I open it and display a message if the file is not there.

The following is what I've tired to accomplish:

autocmd FileType tex nmap <buffer> <F5> if !empty(glob(expand("%:p:r.log"))) | view \| split %:p:r.log<CR> | else | echo expand("%:p:r").'.log does not exist!' | endif

Unfortunately I've got error parsing the init.vim:

Error detected while processing BufReadPost Autocommands for "*":
Vim(else):E581: :else without :if:  else 

Answer 1

Try using <bar> with :*map commands:

autocmd FileType tex nmap <buffer> <F5> if !empty(glob(expand("%:p:r.log"))) <bar> view <bar> split %:p:r.log<CR> <bar> else <bar> echo expand("%:p:r").'.log does not exist!' <bar> endif

and consider writing nnoremap, and using ftplugins with functions:

" ~/.vim/after/ftplugin/tex.vim

function s:open_log(log_file) abort
  if filereadable(a:log_file)
    execute 'sview' a:log_file
  else
    echomsg a:log_file 'does not exist'
  endif
endfunction

nnoremap <buffer> <F5> :call s:open_log(expand('%:p:r.log'))<CR>

Answer 2

I think you just need to change your pattern in the autocmd to *.tex

A file like abc.txt will not match the autocmd pattern tex.

Answer 3

I found a similar problem in this post. Apparently, map class of commands also accept conditional expressions but this has to be flagged by adding <expr> as an option.

In case someone has a similar problem, the following command finally works:

autocmd FileType tex nmap <expr> <buffer> <F5> empty(glob(expand("%:p:r").".log")) ? ":echo expand(\"%:p:r\").'.log does not exist!'<CR>" : ":split \| view %:p:r.log<CR>"

Also, please note I had used a pipe of wrong sequence of commands, that is :view \| split %:p:r.log<CR> instead of :split \| view %:p:r.log<CR> and the main file was changed to read-only mode instead of the log.