How to label tmux tabs with the name of the file edited in vim?

Question

Whenever I open a tmux session in terminal, all of the tabs containing vim sessions are labelled vim.

My question is: How to configure it to label tmux tabs with the name of the edited file or something like vim | test.cpp used as the title of the tabs in question.

Answer 1

There you go :

autocmd BufReadPost,FileReadPost,BufNewFile,BufEnter * call system("tmux rename-window 'vim | " . expand("%:t") . "'")

Decomposing :

autocmd BufReadPost,FileReadPost,BufNewFile,BufEnter * call

On buffer read, file read or buffer new file event (see :help autocmd-events) execute the next command :

call system()

Call a system function and pass it the text :

"tmux rename-window 'vim | "  

Rename the current window with a string starting with vim |

. expand("%:t") 

Add to the string the filename (see this article for the formatting and this post for the expand insert)

. "'"

Add the final ' to close the command.

After expanding it will look like (while editing the .vimrc file):

system("tmux rename-window 'vim | .vimrc'")

As @erthalion said in the comment, you can clean up when leaving vim with :

autocmd VimLeave * call system("tmux rename-window 'tmux'")

Answer 2

To restore the default tmux naming scheme when quitting vim you can also do:

autocmd VimLeave * call system("tmux setw automatic-rename")

Answer 3

This is what I put in my vimrc thanks to the answer by @raphael

I also install the tmux-plugins/vim-tmux-focus-events plugin for the FocusGained and FocusLost events.

augroup tmux
  autocmd!
  if exists('$TMUX')
    autocmd BufReadPost,FileReadPost,BufNewFile,FocusGained * call system("tmux rename-window " . expand("%:t"))
    autocmd VimLeave,FocusLost * call system("tmux set-window-option automatic-rename")
  endif
augroup END

Answer 4

To add something more to other's answers, I've added some vimscript to restore the previous tmux window name instead of the automatic rename:

if exists('$TMUX')
  let windowName = system("tmux display-message -p '#W'")
  autocmd BufReadPost,FileReadPost,BufNewFile,BufEnter * call system("tmux rename-window 'vim(" . expand("%:t") . ")'")
  autocmd VimLeave * call system("tmux rename-window " . windowName)
endif