Follow group links in :highlight command

Question

In :highlight command, colors of some groups are shown as this:

:hi vim9Comment
vim9Comment    xxx links to Comment

I then have to invoke another :hi command, this time with the linked group as the argument. This quickly gets cumbersome if the links go on for three, four, or five levels of depth.

Is there any way to follow the links automatically?

Answer 1

We can write a function that parses the output of :highlight command for "links to" string and follows the link recursively.

function! HiThere(group) abort
  let out = trim(execute('hi ' .. a:group))
  let splits = split(out, ' \+')
  echon splits[0] .. ' '
  execute 'echohl ' .. splits[0]
  echon splits[1] .. ' '
  echohl None
  echon join(splits[2:])
  if out =~ 'links to'
    echom ''
    call HiThere(split(out, ' \+')[-1])
  endif
endfunction
command! -nargs=1 -complete=highlight HiThere call HiThere(<q-args>)

If we don't want the links in the output, i.e., if we only want the colors of the deepest highlight-group, we can bring the echo block in the else part of the if condition below it. I'll leave that for others unless and until someone expresses the need for it.

Answer 2

To get the highlight group that a group links to, you can use this function:

function! GetLinkTarget(group)
    let l:groupID = hlID(a:group)
    " Get the group this highlight group links to
    let l:linkedGroupID = synIDtrans(l:groupID)
    let l:linkedGroupName = synIDattr(l:linkedGroupID, 'name')
    echom a:group . " → " . l:linkedGroupName
endfunction

Example usage:

:call GetLinkTarget("vim9Comment")

Output:

vim9Comment → Comment

---

Explanation:

1. hlID gets the ID of the highlight group whose linked to highlight group we want to find out.
2. synIDtrans(l:groupID) gets the ID of the linked to group.
3. synIDattr(l:linkedGroupID, 'name') translates the ID of the linked to group to its name.