Detect line endings in current buffer, substitute all line endings depending on result

Question

In GVIM, I'd like to save the current file with either \r\n or \n line endings. Depending on the opened file, the appropriate line endings should be chosen automatically. I had a look at https://unix.stackexchange.com/questions/79827/make-vim-act-as-notepad-on-mixed-line-endings but it doesn't quite do what I want.

My preferred behavior would be:

• If the file in the current buffer contains NO carriage returns (\r), save the whole file with line feed (\n) line endings
• If the file in the current buffer contains ANY carriage returns, save the whole file with \r\n line endings

However, I can't get quite this behavior. My current .vimrc looks like this:

" Some settings in my .vimrc that may be important
set encoding=utf-8
set list
set ffs=unix
source $VIMRUNTIME/mswin.vim
behave mswin


" My current status
function! CorrectLineEndings()
    " Carriage return
    let @g = "^M"
    " Testing for carriage return - doesn't work
    if match(getreg('<reg>'),@g) == @g
        " convert to \r\n line endings -> HOW?
    else
        " convert to \n line endings
        :%s/\r//g<CR>
    endif
endfunction
autocmd BufWriteCmd *.* call CorrectLineEndings()

There are two problems with this code - the testing for existing \r endings doesn't work and I'm not sure how to replace all line endings with \r\n. Any help would be greatly appreciated! Thanks in advance!

Answer 1

Convert on reading

Try this:

set fileformats=unix,dos

augroup correct_endings
  autocmd!
  autocmd BufRead * call CorrectEndings()
augroup END

function! CorrectEndings()
  if &fileformat != 'dos' && search('\r$', 'cnw')
    set fileformat=dos
    %s/\r$
  endif
endfunction

This uses Vim's built in detection for all normal files, and then performs a search to check for files with mixed line endings, saving them as dos and then removing the excess carriage returns.

Convert on save

I include the current file's 'fileformat' in my 'statusline' so I can easily check what line endings the current file has without seeing ^Ms in the buffer. However, you've indicated in the comments that you specifically want to edit Windows-format files with 'fileformat' set to unix, so the carriage returns are visible in the file.

You can achieve the above like the below:

set ffs=unix

augroup correct_endings
  autocmd!
  autocmd BufWritePre * call CorrectEndings()
augroup END

function! CorrectEndings()
  if search('\r$', 'cnw')
    execute "g/\\v(\\r)@<!$/norm!A\<C-V>\<C-M>"
  endif
endfunction

This means that you always edit in ff=unix mode, but converts the line endings with a :global command if any CRNL endings are detected on save.

The global command looks a little hairy, but it's actually not that complicated:

g/\\v(\\r)@<!$/norm!A\<C-V>\<C-M>
g/            /                    # For every line where
  \\v                              # (using very magic)
             $                     # the end of the line
          @<!                      # is not preceded by
     (\\r)                         # a carriage return
               norm!               # Run the normal mode command
                    A              # to append at the end of the line
                     \<C-V>\<C-M>  # A literal carriage return character