Different replace patterns depending on visual/visual line mode

Question

I've written some customizations in my .vimrc that I would like to further improve and refine.

In particular, for some key combinations, I'm doing text substitutions, like this:

vmap <C-S-w> :s/\%V.*\%V./Foo & Bar<Enter>:noh<Enter>

It replaces whatever has been marked with "Foo Bar". This works great.

However, I would like to extend this for the macro to be able to distinguish if the selection was made in regular visual mode ("v") or in visual line mode ("V").

Let's say on visual mode I want the above substitution but on visual line mode I want "Fooline & Barline".

I believe the answer lies within a vim function, but I cannot figure out how to approach this.

How to determine the current selection state and how to execute a substitution from a function?

Answer 1

You can use the mode() function.

It returns: v in visual mode and V in visual line mode.

More information with:

:help mode()

mode([expr])    Return a string that indicates the current mode.
        If [expr] is supplied and it evaluates to a non-zero Number or
        a non-empty String (|non-zero-arg|), then the full mode is
        returned, otherwise only the first letter is returned.
        Also see |state()|.

           n        Normal
...
           v        Visual by character
           vs       Visual by character using |v_CTRL-O| in Select mode
           V        Visual by line
           Vs       Visual by line using |v_CTRL-O| in Select mode
           CTRL-V   Visual blockwise
           CTRL-Vs  Visual blockwise using |v_CTRL-O| in Select mode
...

For you case it would mean:

vmap <expr> <C-S-w> mode(1) ==# 'v' ? (':s/\%V.*\%V./Foo & Bar<Enter>:noh<Enter>') : (':s/\%V\_.*\%V./Fooline & Barline<Enter>:noh<Enter>')

Or alternatively using a function:

function! ReplaceSelection()
  if mode(1) ==# 'v'
    return ':s/\%V.*\%V./Foo & Bar' .. "\<Enter>:noh\<Enter>"
  else
    return ':s/\%V\_.*\%V./Fooline & Barline' .. "\<Enter>:noh\<Enter>"
  endif
endfunction

vmap <expr> <C-S-w> ReplaceSelection()