Go to X bytes from here

Question

How can I move X bytes forward, starting from the current cursor location (including line breaks)?

[count]go could be used to move forward X bytes from the start of the buffer. I tried Shift + V, G, [count]go (assuming that [count]go would start counting from the begin of my selection), but unfortunately that did not work either because go only starts counting from the begin of the buffer.

I have also tried :set rulerformat=%o to display the current byte offset (as suggested by Jumping to a byte offset, and displaying position as byte offset), added the numbers in my head and finally issued [count]go. This works, but it is not very practical...

Answer 1

This search moves 40 chars (not bytes, though) forward:

/\_.\{40}/e

by searching for exactly 40 chars (\{40}) of any kind, including newline (\_.), and placing the cursor at the end of the search (/e). See: http://vimregex.com/#Non-Greedy, :help search-offset and :help \_

Also, see :h 23.4 for binary editing.

---

Update: Based on this answer, here's a function that jumps to byte offset:

let s:last_jump_bytes = 0

function! JumpTo(byte_nr)
    let crt_byte = line2byte(line('.')) + col('.')
    if (a:byte_nr == 0)
        let dst_byte = crt_byte + s:last_jump_bytes
    else
        let dst_byte = crt_byte + a:byte_nr
        let s:last_jump_bytes = a:byte_nr
    endif
    let dst_line = byte2line(dst_byte)
    let dst_col = dst_byte -line2byte(dst_line)
    "remove next line if you don't want to record this for `Ctrl-O`
    execute "normal " . dst_line . "G"
    call setpos('.', [0, dst_line, dst_col])
endfunction

command! -nargs=1 JumpToOffset :call JumpTo(<f-args>)

" silly mapping to Ctrl-C (demo)
nnoremap <expr> <silent> <c-c> ":<c-u>call JumpTo(" . v:count . ")<cr>"

Can be used like this:

:JumpToOffset 400

or typing the mapped keyboard mapping, with a count:

40CTRL-C

If you don't use a count, the previous count number is re-used. So you can do: 40CTRL-C CTRL-C CTRL-C 30CTRL-C CTRL-C to jump 40, 40, 40, 30, 30 bytes etc.

Hit Ctrl-O to jump back (see comments inside the function).

Answer 2

I ended up using the following solution, which implements the logic from my question.

• [count]GO to move [count] bytes forward.
• [count]Go to move [count] bytes backwards.

Add this to your .vimrc:

function! JumpToByte(byte_nr)
    " See https://vi.stackexchange.com/a/3911/2720 for the byte counting bug
    let crt_byte = line2byte(line('.')) + col('.') - 1
    if version < 781 && &l:binary == 1 && &l:eol == 0
        let crt_byte += 1
        let crt_byte += line('.') == 1
    endif
    let dst_byte = crt_byte + a:byte_nr
    execute "normal " . dst_byte . "go"
endfunction
nnoremap <expr> <silent> GO ":<c-u>call JumpToByte(" . v:count . ")<cr>"
nnoremap <expr> <silent> Go ":<c-u>call JumpToByte(-" . v:count . ")<cr>"

Thanks to VanLaser for his initial implementation, which put me in the right direction.