How can I open netrw in a split when opening a directory?

Question

I have figured out how to open a file browser in a split, using the following in vimrc:

let g:netrw_liststyle = 3
let g:netrw_banner = 0
let g:netrw_browse_split = 4
let g:netrw_winsize = 25
let g:netrw_altv = 1
augroup ProjectDrawer
  autocmd!
  autocmd VimEnter * :Vexplore
augroup END

This is nice since I can then work with multiple files without having to exit and reopen vim all the time.

The issue is when I want to edit a specific file. Then I do not need or want the file browser.

So my question is: is there a way to wrap this in an if statement which would only open netrw in a split if the argument to vi is not a file:

1. vi path/to/folder/ - Include
2. vi path/to/folder - Include
3. vi - Include
4. vi path/to/folder/my_file - Skip

Answer 1

I would propose the following code:

let s:hasfolder=1
let g:foldertoopen = '.'

function s:parse_arguments()
  let i = 1
  while i < len(v:argv)
    if v:argv[i][0] == '-'
      let i = i + 2
    else
      let path = v:argv[i]
      if path[len(path)-1] == '\' || path[len(path)-1] == '/'
        let path = path[:-2]
      endif
      if finddir(escape(fnamemodify(path, ':t'), ' '), escape(fnamemodify(path, ':h'), ' ')) != ''
        let s:hasfolder = 1
        let g:foldertoopen = v:argv[i]
        break
      else
        let s:hasfolder = 0
      endif
      let i = i + 1
    endif
  endwhile
endfunction

call s:parse_arguments()

let g:netrw_liststyle = 3
let g:netrw_banner = 0
let g:netrw_browse_split = 4
let g:netrw_winsize = 25
let g:netrw_altv = 1

function! InitBrowser()
  if g:foldertoopen != ''
    enew
    exe 'Vexplore ' . g:foldertoopen
    let g:foldertoopen = ''
  endif
endfunction

if s:hasfolder
  augroup ProjectDrawer
    autocmd!
     autocmd VimEnter * :call InitBrowser()
  augroup END
endif