Why do I get a missing quote error when using the following in a mapping using execute and normal?

Question

The command is

nnoremap <leader>; :execute "normal! mqA;\<esc>`q"

If you then press <leader>;, you will E114: Missing quote: "normal! mqA;\ followed by E15: Invalid expression: "normal! mqA;\. Why is this? The command works fine if input directly into the commandline.

The command adds a ; at the end of the current line, without changing the cursors position.

I realise that I can just do nnoremap <leader>; mqA;<esc>`q which works, the question is why the above doesn't work, and what can be done to make it work in the execute-normal form.

My guess would be that some level of nested escaping is needed, but I couldn't find one that works.

Answer 1

You need to escape the < via <lt>:

nnoremap <leader>; :execute "normal! mqA;\<lt>esc>`q"<cr>

Note: added <cr> to execute the command as well.

However this can be simplified quite a bit:

nnoremap <leader>; mqA;<esc>`q

Using an expression mapping you can make your mapping conditional based on a trailing ; character:

nnoremap <expr> <leader>; getline('.') =~ ';$' ? '' : "mqA;\<esc>`q"

For more help see:

:h <lt>
:h map-<expr>

Answer 2

You need to escape the <ESC> in command mode. This is done by prefixing it with <C-v>. You also need a trailing <CR> to actually run it. Like this:

nnoremap <silent> <leader>; :execute "normal! mqA;<C-v><ESC>`q"<CR>

Answer 3

I found that there are 3 ways to escape the key:

1. nnoremap <silent> <leader>; :execute "normal! mqA;<C-v><esc>`q"<CR>
2. nnoremap <silent> <leader>; :execute "normal! mqA;\<lt>esc>`q"<CR>
3. nnoremap <silent> <leader>; :execute "normal! mqA;\e`q"<CR>

Similar for the Enter key (<cr>):

<c-v><cr> or \<lt>cr> or \r.