How can I open a split terminal with :term and then run a command in that terminal?

Question

I'm trying to write a function to open a split terminal in Vim and then run the current file in that terminal. A non-working example trying to explain what I'm trying to do is

function! Foo()
    :bel term
    %
endfunction

This just opens up the terminal. I tried with another command, dir, and it seems it's fails because dir is not a Vim command, so it's still trying to run things in Vim rather than the terminal. I also tried putting the command on the same line e.g. :bel term % but I get an error:

Error detected while processing function Foo:
line 2:
CreateProcess failed

And the terminal doesn't even open.

I also tried

function! Foo()
    :bel term
    !dir
endfunction

though that had the expected result of essentially running !dir and then returning me to a split window with nothing in the terminal there.

I've also tried to use the feedkeys() function but I can't find a way to automatically pass the file name in.

I can't see anything relevant on :help terminal. I've also found two relevant posts (post 1, post 2) but both seem to use Linux/bash and I'm on Windows, and those solutions aren't working.

How could I achieve this? If it's relevant I'm running Vim on Windows through cmd.

Answer 1

Each line in vimscript is a vim command, not a series of keystrokes. Running :terminal doesn't automatically mean any following commands will be sent to the terminal buffer.

In order to send keystrokes to a terminal, we need its buffer number and term_sendkeys(). The easiest way to get a terminal's buffer number programatically is to start it with term_start():

function Foo() abort
  " replace with let if your vim is old
  const term_buf = term_start(&shell)
  call term_sendkeys(term_buf, expand('#')."\<CR>")
endfunction

You can also use method syntax in this case:

call term_start(&shell)->term_sendkeys(expand('#')."\<CR>")

• expand('#') gets the previous files name (term_start() has already switched to the terminal buffer)
• ."\<CR>" embeds a carriage-return (enter) keypress, too
• term_start() takes a fair number of options, so you can use, e.g., #{vertical: v:true} for a vertical split.

When you do :terminal %, it tries to run the file expanded to by % as a program; it's possible the file isn't found (e.g., if the file is in the current directory and that directory is not in PATH). Using :terminal %:p might work around that.