Function-local inner functions

Question

These exist with lambdas

function A()

  let B = { -> 'thing' }

endfunction

// B does no exist

But the lambda returns a value and not a sequence of commands.

(I know I could put execute("..") in the lambda but this is an ugly hack.)

function A()

  function B()
    echo "I'm going to leak"
  endfunction

endfunction

// B exists everywhere now

Now we can call B() from outside A, so it's not local to the function.

So, is it possible to have a function-local inner functions?

(I want to pass closure callbacks without redefining a script-local function every time.)

Answer 1

One way to prevent creation of a global function is to use "dictionary entry funcref syntax." Note that this is distinct, but also useful paired with, functions which are marked dict.

function A()
  let l:container = {}

  function container.myfunc()
    echo "I'm going to leak"
  endfunction

  call l:container.myfunc()
  return l:container.myfunc
endfunction

Internally, vim is creating a "numbered" function stored in a funcref type variable. This is very similar to how a lambda is implemented. Although you can return the funcref value and safely call it outside, once all references are gone, it is cleaned up.

You can also use the closure keyword to allow use of outside variables, like is the default for a lambda. Use care, because it is rather easy to create circular references in this way, and vim will not clean up resources if references exist.

function A()
  let l:value = 10
  let l:container = {}

  function container.myfunc() closure
    echo "Variable" l:value
  endfunction

  call l:container.myfunc()
endfunction

Answer 2

Yes, of course.

function! Outer() abort
    let l:time = strftime("%c")

    function! s:inner(param) abort closure
        echom "Inner closure was created at" l:time
        echom "Param is" a:param
    endfunction

    return funcref("s:inner")
endfunction

let g:Inner = Outer()
call g:Inner(42)