How to display multiple changed files on disk in Vim?

Question

Related to this thread, How can Vim tell me which buffer is changed on disk among multiple buffers?

This Vim configuration automatically checks for changes in opened buffers and notifies when a single file has been modified externally.

set autoread
autocmd FocusGained,BufEnter,CursorHold,CursorHoldI *
  \ if mode() !~ '\v(c|r.?|!|t)' && getcmdwintype() == '' | checktime | endif
autocmd FileChangedShellPost *
  \ echohl WarningMsg | echo "File " . expand('<afile>') . " changed on disk. Buffer reloaded." | echohl None

Desired Feature
When multiple files are changed externally, for example, with the tabs open for files A.cpp, B.cpp, C.cpp, and D.cpp.

If two files (A.cpp and C.cpp) are modified outside Vim, the notification should show: "File A.cpp C.cpp changed on disk. Buffer reloaded."

Answer 1

I would do:

set autoread
autocmd FocusGained,BufEnter,CursorHold,CursorHoldI *
  \ if mode() !~ '\v(c|r.?|!|t)' && getcmdwintype() == '' | checktime | endif

let g:filechanged_timer = 0
let g:filechanged = ""

function! FileChangedCallback(timer)
  echohl WarningMsg
  echo "File " . g:filechanged . " changed on disk. Buffer reloaded."
  echohl None

  " Reset the timer and the list of files:
  let g:filechanged_timer = 0
  let g:filechanged = ""
endfunction

function! FileChanged(path)
  if g:filechanged_timer == 0
    " First change detected
    let g:filechanged = a:path
    " Wait 0.1 seconds for a new changes to come:
    let g:filechanged_timer = timer_start(100, 'FileChangedCallback')
  else
    " Some more change detected
    " Add the file path to the list:
    let g:filechanged = g:filechanged .. ', ' .. a:path
  endif
endfunction

autocmd! FileChangedShellPost * call FileChanged(expand('<afile>'))