Cycle through a list of letters in multiple groups

Question

So I have a case where I have some unicode letters say [B, Ḅ, Ḃ] and when I have my mouse selected over the B, (in normal mode) I want some way of cycling through the list. Like pressing some command should replace B with Ḅ, pressing it again should replace Ḅ with Ḃ.

---

I looked at this https://github.com/zef/vim-cycle/blob/master/plugin/cycle.vim, but it was not quite what I was looking for as

1. It works on words not letters
2. I sometimes need multiple groups

---

Say this is group associated with hotkey A [$ Ɗ Ʋ] I also need a second group B, with a second hotkey which would cycle [$ ¥], [Ɗ ɗ] and [Ʋ ʋ].

Finally (and I might ask this in a follow up question), very rarely I would need to do a two group cycle. Something like [С, п, Ðḟ, ...] Which would always start with a Ð. Any ideas, or resources to look for?

I tagged this with vimscript Lua, simply because I am open to solving this issue with Lua if it makes it easier.

Answer 1

At least for single characters, here's what I would do. First, let's build a little function for an expression map. It takes a dictionary corresponding to the cycle, examines the character under the cursor, and returns the sequence of commands to do. This is either a r command or nothing.

function CyclePair(which_pairs) abort
  let char_under_cursor = strpart(getline('.'), col('.') - 1, 1, v:true)
  return has_key(a:which_pairs, char_under_cursor)
        \ ? 'r'.a:which_pairs[char_under_cursor]
        \ : ''
endfunction

Then we can map it like

nnoremap <expr> <leader>r CyclePair({'a': 'b', 'b': 'c', 'c': 'a'})
" ... more mappings, different pairs, no big deal.

Typing the dictionary is a slight pain and easy to get wrong. It would be nicer to just use a list.

function MakePairs(xs) abort
  let len = len(a:xs)
  return range(len)->reduce({ acc, val -> extend(acc, {a:xs[val]: a:xs[(val+1)%len]}) }, {})
endfunction

So now we can write

nnoremap <expr> <leader>r CyclePair(MakePairs(['a', 'b', 'c']))

Answer 2

So I found a solution thanks to How to add accent to letters in normal mode? using tr. As stated in the comments a simple 3 cycle would be done by

tr(@", 'ABC', 'BCA')

Which cycles A -> B -> C -> A. Wrapped in a command it looks like

nnoremap <silent> <localleader>ln s<c-r>=tr(@", 'ABC', 'BCA')

However, this gets a bit nasty when trying to add several cycles into the same command as in my real example beneath

nnoremap <silent> <localleader>ln s<c-r>=tr(@", '3456789³⁴⁵⁶⁷⁸⁹AẠȦÄBḄḂƁCÇĊƇDÐḌḊƊEẸĖ', '³⁴⁵⁶⁷⁸⁹3456789ẠȦÄAḄḂƁBÇĊƇCÐḌḊƊDẸĖE')<cr><esc>
" nnoremap <silent> <localleader>lp s<c-r>=tr(@", 'ABC', 'BCA')<cr><esc>

nnoremap <silent> <localleader>lq s<c-r>=tr(@", '©ß¢ÇçÑñ£Ŀŀ¦¡¿/ƒ\¤$ƊƲ¥ɗʋ#?Ƒ⁺@`"þ{}€ÞƝƤƙɼƭⱮƇƬ', 'ߢÇçÑñ£Ŀŀ¦¡¿/ƒ\¤$ƊƲ¥ɗʋ#?Ƒ⁺@`"þ{}€ÞƝƤƙɼƭⱮƇƬ©')<cr><esc>
" nnoremap <silent> <localleader>la s<c-r>=tr(@", 'ABC', 'BCA')<cr><esc>

Do note that everything works, but I will be asking a separate follow up question on how to make the formatting more bearable, because this will turn into a nightmare debugging, =)

^{and I have only added A-E still got D-Z...}