Vertical WildMenu in Vim

Question

One thing that really bothers me in vim (probably the only thing), is the wildmenu.

In neovim, the wildmenu is vertical and looks as following:

However, in vim, it is horizontal and looks like this:

Is it possible to get the vertical wildmenu in vim?

If possible, without a plugin, but if there is no other way then I don't mind.

Answer 1

It's not available in Vim. However, there is a fork called Vim-CLPUM. You need its clpum branch, which is 2 years behind Vim's master at the moment. If you really like this feature, maybe you could help h-east with testing it or in some other way.

Answer 2

Patch 8.2.4325 added the vertical wildmenu support to Vim.

Answer 3

Not exactly what OP asked but... maybe someone will find this useful.

There are countless plugins (commonly referred as "pickers") that allow user to pick an item from (vertical) popup menu and to execute some arbitrary command afterwards (vim-clap, nvim-telescope, you name it). Probably many of us also tried to create "fast buffer switch" or "colorscheme chooser" that works without even entering cmdline. Now with Vim8 +popupwin it's easy!

The main disappointment is that (callback) lambdas are really awkward to re-use: imagine we have a dozen of individual "pickers" each of which calls a generic Pick() function which in turn calls popup_menu(). Now every "picker" wants to have specific callback lambda but every lambda should also have access to all locals in Pick() too! Luckily, we can work around it using good old "substitute-eval-submatch" trick.

So the code for our generic Pick() function is

" Pick({name} [, {items} [, {cmd}]])
" pick parameter and execute {cmd}
function! Pick(...) abort
    let l:name = a:1
    let l:items = a:0 > 1 ? a:2 : getcompletion(l:name..' ', 'cmdline')
    let l:cmd = a:0 > 2 ? a:3 : '%{name} %{items[result - 1]}'
    call popup_menu(l:items, #{title: printf('[%s]', l:name), maxheight: &pumheight ?
        \ &pumheight : &lines / 2, minwidth: &pumwidth, callback: {id, result ->
        \ (result < 1 || result > len(items)) ? v:null :
        \ execute(substitute(l:cmd, '%{\([^}]\+\)}', '\=eval(submatch(1))', 'g'), '')}})
endfunction

So the third (optional) parameter is a String to evaluate and execute in the context of Pick()'s internal lambda. And inside our "special" %{...} expression we can actually access all those local variables! That allows for super-easy writing of menu callbacks.

" Choosing :colorscheme is trivial
nnoremap <silent><plug>colorscheme <cmd>call Pick('colorscheme')<CR>

" Choosing from :scriptnames using custom items and cmd
nnoremap <silent><plug>scriptnames <cmd>call Pick('scriptnames',
    \ map(split(execute('scriptnames'), "\n"), 'v:val[1:]'), '%{result}%{name}')<CR>

" Choosing buffer is a bit verbose as we have to prepare buffers list
nnoremap <silent><plug>buffers <cmd>call Pick('buffer', map(getbufinfo({'buflisted': 1}),
    \ {_, v -> printf('%2d %s', v.bufnr, empty(v.name) ? gettext('[No Name]') :
    \ fnamemodify(v.name, ':t'))}), '%{name} %{split(items[result - 1])[0]}')<CR>

And all others like "args", "find", "history", "marks", "oldfiles", "registers", "windows" and even "picker of pickers". The code is in my vimfiles repo. This gives us roughly a half of functionality of those plugin monsters such as nvim-telescope with only a few lines of "poor old" VimScript.

Answer 4

Thank you for posting this question. The same thing is bothering me as well.

At first, I thought there was a new plugin - wilder, but it appears (to me) that the vertical-nature is not given.

I did not try to install the python dependencies.

Nonetheless, I am recommending to try the following pair of options:

set nowildmenu
set wildmode=list:full

This is the best aid and almost mimics the vertical menu when completing the cmdline.

---

update on 03. Juli 2022, because vim 9 was released.

The changelog did not prompt me with this feature, but the following thread: How to get vertical wild menu using wildoptions=pum on Vim 9.0.

After a short search, the following PR (attribution!), even though it was not merged, initiated the support for this menu: https://github.com/vim/vim/pull/9707.

You need to activate an alternative behaviour by

set wildmenu

Then configure it like so:

set wildoptions=pum

Have fun!