Manipulate the dot command without editing text in insert mode

Question

I need to manipulate the dot command without directly editing the buffer for a plugin I'm developing.

The plugin needs to manually append text to the dot command that will be executed while in insert mode.

I would like to have as little side effects as possible.

Is this possible?

Answer 1

As I understand it, the problem is that your plugin will do an operation which leaves the "dot" repeat command in an inconsistent state. From the question, I don't know what this operation is, but generally you can re-structure your plugin in a way that it will work as expected.

You can use the g@ operator feature to run arbitrary commands which are repeatable. The following is an example using wincmd, however you can replace this with another command or function call.

This is a completely native method which should be preferred to e.g., vim-repeat which require re-mapping the dot command.

function! RepWincmd(...)
    execute (v:count ? v:count : s:rep[1]) 'wincmd' s:rep[0]
endfunction

function! s:setup(rep, ...)
    let s:rep = [a:rep, v:count ? v:count : get(a:000, 0, 1)]
    set operatorfunc=RepWincmd
    return 'g@l'
endfunction

" optional number is the default shift amount
nnoremap <expr> <c-w>- <sid>setup('-', 3)
nnoremap <expr> <c-w>+ <sid>setup('+', 3)
nnoremap <expr> <c-w>< <sid>setup('<', 5)
nnoremap <expr> <c-w>> <sid>setup('>', 5)

Answer 2

You will have to remap a . to do series of changes that your mapping introduces.

It is not that simple to do and it might interfere with other things user might have mapped on the dot like vim-repeat of Tim Pope (which does exactly that and exposes API for other plugins to have complex repeats with a dot)