How to implement an autocommand that deletes a buffer when it's being hidden and when it hasn't been modified in the last N seconds?

Question

I'm trying to implement a simple autocommand, which deletes a buffer when it's hidden, with a condition that the file hasn't been modified in the last N seconds. I have the following code in ~/.vim/autoload/tools.vim:

function tools#TimeSinceModified(file)
  return localtime() - getftime(a:file)
endfunction

let s:delete_buf_after_s = 1800

function tools#DeleteBuffer(bufnr)
  if !&modified && tools#TimeSinceModified(bufname(a:bufnr)) > s:delete_buf_after_s
    execute 'bdelete' a:bufnr
  endif
endfunction

Then, in my .vimrc, I have this autocommand:

autocmd BufHidden * call tools#DeleteBuffer(expand("<abuf>"))

This doesn't work, however. The buffer isn't deleted, and the editor prompts the following error whenever a buffer is being hidden:

Error detected while processing function tools#DeleteBuffer:
line    2:
E937: Attempt to delete a buffer that is in use

Is there some way of getting around this error? How can I get this functionality to work?

Answer 1

I would use a timer to avoid messing with the buffer during the BufHidden event; something like

function tools#DeleteBuffer(bufnr)
  if !&modified && tools#TimeSinceModified(bufname(a:bufnr)) > s:delete_buf_after_s
    call timer_start(100, {_ -> execute('bdelete '.a:bufnr)})
  endif 
endfunction

We have to use the execute() function here because a lambda-body is an expr1 (:help lambda), and that also means we have to do our own string concatenation.

A cleaner solution would be to start the timer in the autocommand (which makes the function stand on its own, to me):

autocmd BufHidden * call timer_start(100, {_ -> tools#DeleteBuffer(expand("<abuf>"))}

But I worry about the expand("<abuf>") not working inside the lambda at that point, and I don't have a workaround yet.