How can I turn these mappings into a vim function?

Question

I use the following mappings to toggle relative numbers in visual mode:

nnoremap <silent> v v:<c-u>set nonu rnu<cr>gv
nnoremap <silent> V V0:<c-u>set nonu rnu<cr>gv
nnoremap <silent> <c-v> <c-v>:<c-u>set nonu rnu<cr>gv
vnoremap <esc> <esc>:set nornu nu<cr>

I would like to use the same mappings, but add a conditional check before performing the operation to exclude certain buffers types from this behavior.

I tried adding this to a function but was not successful.

Does anyone know how I can achieve this?

Answer 1

Function bodies are pure Ex, so you need (e.g.)

normal! v
set nonumber norelativenumber
normal! gv

Though note that between :normal! v and :normal! gv, the commands aren’t like the mapping where you are literally typing : and then have to delete the range <C-u> etc.

Simpler here would just be

set nonumber norelativenumber
normal! v

However, this may not leave you in visual mode! :normal! works better with complete commands.

As a solution, you could try and expr mapping and

return 'v'

Or just insert the function call between v and gv with :<C-u>call MyFunction()<CR>.

Answer 2

Here's what I put together based on @D.BenKnoble answer (with help from @filbranden):

function! s:relativeLineNumbers()
  if (&filetype != 'coc-explorer')
    set nonu rnu
  endif
endfunction
command RelativeLineNumbers call s:relativeLineNumbers()

nnoremap <silent>v v:<c-u>RelativeLineNumbers<cr>gv
nnoremap <silent>V V0:<c-u>RelativeLineNumbers<cr>gv
nnoremap <silent><c-v> <c-v>:<c-u>RelativeLineNumbers<cr>gv
vnoremap <esc> <c-c>:set nornu nu<cr>

Note: I selected his answer rather than my own however.