why doesn't regex work in vimscript (while it does in normal search)?

Question

I have simple regex to search for lines that only contain alphabetic characters: ^\(\a\)\{1,}$ which works in normal search /^\(\a\)\{1,}$ but not when invoked from my script:

"in .vimrc file:
function DiaryTagBrowser()
  let line = getline('.')
  "if line =~ "^\(\a\)\{1,}$"
  if match(line, "^\(\a\)\{1,}$")
    w! /tmp/vimwiki-tag-list.txt
    enew | set ft=vimwiki | set modifiable
    exe 'read !tagshow.py ' . line
    set nomodifiable
  else
    echo "not on a diaryTag"
  endif
endfunction
command! DiaryTagBrowser : call DiaryTagBrowser()
nnoremap <Enter> :DiaryTagBrowser <Enter>

Testing on a file that looks like:

tagOne
tagTwo
tagThree
not a tag
tagFour

When doing a normal search via / the lines 1, 2, 3, and 5 all match, while line 4 does not match. This is correct/proper/as-expected.

But that same regex in my vimscript doesn't work. When using:

if match(line, "^\(\a\)\{1,}$") the code always runs (the regex also evaluates to true) though it should never run when <Enter> is pressed on line 4.

And when using:

if line =~ "^\(\a\)\{1,}$" the code never runs (regex is always false, always echoing "not on a diaryTag") though it should always run <Enter> is pressed on lines 1-3 and 5.

I've tried many different alterations of the regex expression, but considering the inconsistency I just described the problem does not seem to be with the expression but with how it's invoked.

In this maddening endeavor I've read through: 1 2 3 4 5 6 7 8 9 and several other posts... without finding an explanation of this at all.

What's going on here?

Answer 1

One of the links referenced put the expression in double quotes ". Using single quotes ' instead fixes the problem with if line =~ '^\(\a\)\{1,}$'.

In order for match() to be used in logic like this it needs to be compared to something like:

if match(line, '^\(\a\)\{1,}$') == 0 since match() returns 0 when it finds a match at the first character or list item (which is the case in this example).