Equivalent of visual-block-mode "I" in visual, visual-line mode

Question

In visual-block mode, it's very convenient to press I to be able to modify text at the beginning of the selection(s). What is the equivalent way to do this in normal Visual mode? For example, the closest I've found is probably something like:

[Esc]`<i

And I'm not sure there exists a way to do it i Visual-line mode? What would be the simplest way to do this: is there a way with a single keystroke like there is in visual-block mode? And the same with A to insert (append) at the end of the visual selection(s)?

Answer 1

Not sure to have correctly understood, but try this:

let s:niceblock_keys = {
    \   '$'  : {'v': 'g$h',      'V': '$',          "\<c-v>": '$h'},
    \   'I'  : {'v': "\<c-v>I",  'V': "\<c-v>^o^I", "\<c-v>": 'I'},
    \   'A'  : {'v': "\<c-v>A",  'V': "\<c-v>0o$A", "\<c-v>": 'A'},
    \   'gI' : {'v': "\<c-v>0I", 'V': "\<c-v>0o$I", "\<c-v>": '0I'},
    \   '>'  : {'v': "\<c-v>>",  'V': "0\<c-v>>",   "\<c-v>": '>'},
    \   '<'  : {'v': "\<c-v><",  'V': "0\<c-v><",   "\<c-v>": '<'},
    \ }
fu s:niceblock(key) abort
    return s:niceblock_keys[a:key][mode()]
endfu

xno <expr> $  <sid>niceblock('$')
xno <expr> I  <sid>niceblock('I')
xno <expr> gI <sid>niceblock('gI')
xno <expr> A  <sid>niceblock('A')
xno <expr> >  <sid>niceblock('>')
xno <expr> <  <sid>niceblock('<')

Adapted from the vim-niceblock plugin.