How do I run a command on creation of a new file?

Question

I'm aiming to make scripts I write in a certain directory (or of a certain extension) automatically executable on creation. I can do this whenever a file is written to, using the following autocmd:

autocmd BufWritePost *.py silent execute "! chmod +x %"

What I don't like is that this runs every time the file is written. If I had decided to reset the permissions of a particular script, I wouldn't want it to be set again, for example. And if the command is expensive, or is not idempotent, it would be undesirable to run it again and again. While this particular example uses chmod, please consider a more general case.

There is an event for when a buffer is created for a new file (BufNewFile), but is there some way to do this when such a buffer is written the first time?

Answer 1

This would set the file to be executable after writing to the file if it's not already executable

autocmd BufWritePost *.py
    \  if getfperm(expand('%')) !~# 'x'
    \|   silent execute "! chmod +x %"
    \| endif

I think this should be the better approach.

To make only a new file executable:

autocmd BufWritePre *.py
    \  if !filereadable(expand('%'))
    \|   let b:is_new = 1
    \| endif
autocmd BufWritePost *.py
    \  if get(b:, 'is_new', 0)
    \|   silent execute '!chmod +x %'
    \|   let b:is_new = 0
    \| endif

Answer 2

I use a different solution for this, with a script I called xvim:

#!/bin/sh

vim -p "$@"
for f in "$@"; do
    [ -f "$f" ] && chmod a+x "$f"
done

I put this in my ~/bin (make sure this is in your PATH), and also linked xvi to it.

The advantage of this, is that I explicitly control which files are executable, rather than just assuming that all .*.py files should be executable (files in modules usually aren't). You also don't need to set it up for all filetypes (*.rb, *.sh, etc.).

If you don't want xvim to overwrite existing permissions, you can use:

#!/bin/sh

for f in "$@"; do
    [ -f "$f" ] && continue
    touch "$f"
    chmod a+x "$f"
done
vim -p "$@"

Note that this will create the files immediately when you run xvim file (this is different from vim).