Function to remove all trailing whitespace

Question

I have the following function to remove every trailing white space from the document, without changing my cursor position

function! StripTrailingWhitespaces()
  let l = line('.')
  let c = col('.')
  %s/\s\+$//e
  call cursor(l, c)
endfunction

I'd like to change it so that it doesn't remove any whitespace to the left of my current cursor position. For example consider this situation, (a _ stands for a space and | is the cursor position)

test__|_

there's the string test followed by three spaces, and the cursor is between the second and the third space. If I execute that function, I end up with

test|

and all the spaces have been removed, instead I'd like to end up with

test__|

where only the space to the right of the current cursor position has been removed (all the other trailing whitespaces throughout the document should be removed in both cases, I only want to change the behaviour on the current line).

How can this be done?

Answer 1

You can use the zero-width \%# to match the cursor position, so something like

substitute/\%#\s\+$//e

on the current line, and your other pattern on the other lines:

global/\%#/substitute/\%#\s\+$//e
vglobal/\%#/substitute/\s\+$//e

Unfortunately, by the time either :substitute is happening, the cursor position has moved. So let's save it and make the matches more exact with \%123l and \%123c for matching exact lines and columns:

let [_, line, col, _, _] = getcurpos()
execute printf('global/\%%%dl/substitute/\%%%dc\s\+$//e', line, col)
execute printf('vglobal/\%%%dl/substitute/\s\+$//e', line)

But now that we already have the line number, we don't need the first :global:

let [_, line, col, _, _] = getcurpos()
execute printf('%d substitute/\%%%dc\s\+$//e', line, col)
execute printf('vglobal/\%%%dl/substitute/\s\+$//e', line)

Then you can surround it with winsaveview() and winrestview() to handle the cursor position.

PS technically the first substitute does not need the line number, but being explicit does not hurt.

Answer 2

You can do it with several substitutions.

" bookmark current position
normal! m`
" remove whitespace on the current line
silent! keepj s/\%#\s\+$//
" same for lines above
silent! keepj 1,- s/\s\+$//
" same for lines below
silent! keepj ''+,$ s/\s\+$//
" restore cursor position
normal! g``