Execute the contents of a register with a delay after each command

Question

So far, I managed to implement a function that adds a delay after "putting" each character contained in a register to the screen:

function! AnimateInsertion() abort
    " split contents of last modified reg in individual chars
    let s:line = split(getreg(v:register), '\zs')
    " iterate through each character
    for s:char in s:line
        sleep 100m
        exe 'normal!a'.s:char
        redraw
    endfor
endfunction

However, this approach treats the contents of the register as a literal string. In other words, this implementation prints an 'i' instead of actually treating it as a command that makes Vim go into insert mode. How could I execute the contents of the register as commands (just like @<reg> does) and add a delay after each command is executed?

UPDATE: I encountered this 3-year-old question yesterday. It asks pretty much the same as this one. Unfortunately nobody has been able to come up with a solution yet.

Answer 1

This is fun:

com -nargs=+ Type call s:type(<q-args>)

let g:type_interval='200ms'

function s:type(cmd) abort

  " spawn a timer_start for every char, the inner lambda call feedkeys with
  " captured current char.
  call map(split(a:cmd, '\zs'),
        \ { i,v -> timer_start( g:type_interval * i, { t -> feedkeys(v) } ) })
endfunction

exe "Type Gohello\<esc>oworld\<esc>ciwvim\<esc>dddd"

source it, it will jump to end of file, typing hello world, then change world to vim, then delete lines one by one. If you type in the middle, you will mess it, I hope that's not a problem.

This works like every character is typed one by one, it doesn't care about mapping delay and keycode delay, something like this will never wrok:

" turn on timeout, make sure timeoutlen is greater than type interval
set timeout
let &timeoutlen=1000
let g:type_interval='100ms'

nnoremap abc dd
Type abc

The a never get it's bc, can't tell why. It also breaks if you use multi bytes keycodes (such as "\<c-right>").

Update to address comment

If you want to place the command in a register and hide the execution part:

let @x = "Type Gohello\<esc>oworld\<esc>ciwvim\<esc>dddd"
nnoremap <silent> <leader>x :exe @x<cr>

To support abort

We can't use command to abort, the animation will mess our typing, we can only use single key map to do it, we need to create map in all mods:

noremap <f4> <c-\><c-n>:call timer_stopall()<cr>
noremap! <f4> <c-\><c-n>:call timer_stopall()<cr>
tnoremap <f4> <c-\><c-n>:call timer_stopall()<cr>

I use timer_stopall() for simplicity here. If you want to be precise, you can record it in the s:type and loop them one by one to stop it.