How to show only matching lines?

Question

Is there a way to hide all lines that did not match, while going through the list of result lines?

In a long file, I would like to search for a pattern that will match roughly 200 lines or so. The matched lines are in random places in the file.
When a line matches, only the line itself is relevant, no context above or below.

Normally, I would search with / and jump through the matches with n.
But that means there are only one or two relevant lines on the screen at a time.

A brute force approach would be to delete all non-matching lines, and undo that deletion later. But that's ugly in various ways, even if it would not end up in persistent undo.

Answer 1

:vimgrep pattern %
:cwindow

vimgrep will search for your pattern in the current file (%), or whatever files you specify.

cwindow will then open a buffer in your window that will only show the desired lines. You can use pretty much any navigating/search command within the cwin buffer. Press return to jump to the line under your cursor in the source file.

For help:
:help vimgrep
:help cwindow

Answer 2

You can list all matching lines with

:g/{pattern}

(The :print command can be omitted; it is the default for :g.)

Answer 3

[d]elete all lines not(!) matching patterns:

:g!/pattern/d

or even simpler (thanks for the comments by 'B Layer'):

:v/pattern/d

Answer 4

You can use the foldmethod and foldexpr options to fold away irrelevant lines.

After searching, the last search is stored in the @/ register. So, you can readily fold away everything that doesn't match like this (for one-line matches only):

:setlocal foldexpr=getline(v:lnum)=~@/?0:1 foldmethod=expr

More advanced methods, like adding multiple levels of folding for context lines you can show or hide, or matching multiple lines, can be found on the Vim Tips Wiki.

Answer 5

If order doesn't matter then just move the lines.

:g/pat/m0

For more help see:

:h :g
:h :m

Answer 6

If you want to list all matching lines (as in my other answer), and then jump to one particular match, my FindOccurrence plugin provides a [/ mapping for that (and [n for the last search pattern, instead of querying for one). [/pattern lists like :g/pattern, but then asks for the number of the match to jump to.

Answer 7

Another way is to use :h :ilist, i use it to get an overview of man page. it's result looks like this:

~/find.~
  1:    3 NAME
  2:    6 SYNOPSIS
  3:    9 DESCRIPTION
  4:   18 OPTIONS
  5:   93 EXPRESSION
  6:  779 EXAMPLES
  7:  877 HISTORY
  8:  931 BUGS

Here is a small function that let you choose to go to the result line by index:

function! s:select_ilist(ilist_result)
  if empty(a:ilist_result) || a:ilist_result =~# '^\_s*Error'
    return
  endif

  let select = input(a:ilist_result . "\ngoto : ")
  if empty(select) | return | endif

  " ilist result starts with '\nfilename\n', filename can be empty
  let lines = split(a:ilist_result[stridx(a:ilist_result, "\n", 1) : ], "\n")
  if select <= 0 || select > len(lines) | return | endif

  exec matchstr(lines[select-1], '^\v\s*\d+\:\s+\zs\d+')
endfunction

It can be used like this:

command! -buffer Section call s:select_ilist(execute('silent! ilist /\v\C^[A-Z][^a-z]+$/'))