Is there a way to list recent buffer history?

Question

I just started using buffers in Vim and I couldn't figure out how to list recent closed buffers. Is there a simple way (like :ls) to list those? Are they actually stored by Vim?

Maybe I'm misusing buffers, but what I want to do is to glance at recent closed buffers and then reopen (:e) one of those (of which at that moment I don't remember the (file)name).

I searched windows.txt (from :help buffers) for terms like history, closed buffer, buffer closed, but none of them got me closer to doing what I want.

---

Edit: I tried :oldfiles (as D. Ben Knoble suggested) but that doesn't seem to work as I'd expect. When I'm viewing one file (buffer) A.file and open another one B.file (using NERDTree) and just after that I close B.file, then :oldfiles doesn't show B.file on the list.

Answer 1

As of patch 8.1.2225, you can use :ls t to list buffers in order of most recently used.

This includes "closed" buffers where closed means not in any window currently. It does not include buffers from prior closed instances of vim.

Answer 2

You can try to improve my naive attempt:

"" if you want real list
" let g:mru_buffers = []
"" or just a string with newlines
let g:mru_buffers = ""
func! RecordMRU(file)
    if a:file != '' " here you can add another check if buffer/file is in mru and either do nothing or move it in the list/string to top
        " call insert(g:mru_buffers, a:file)
        let g:mru_buffers .= a:file . "\n"
    endif
endfunc
augroup mru_list | au!
    au BufDelete * call RecordMRU(expand('<afile>'))
augroup end

Having this you can list recently closed buffers with echo g:mru_buffers, or make a command :command MRU :echo g:mru_buffers.

It doesn't have persistence but one can easily add it.

Answer 3

Use _u to open last buffer,_U to view last buffers.

It can be improved.

let g:lastWindows= []
let g:lastWinName = ""

function! SaveLastWindow()
  if &bt == '' || &bt == 'help' || &ft == 'netranger' "|| &bt == 'nofile'
    let cur= expand( '<afile>' )

    if cur == g:lastWinName || cur ==""
      return
    endif 

    call add(g:lastWindows,cur) 

    let g:lastWinName=cur
  endif
endfunction 

augroup bufclosetrack
  au!
  autocmd BufWinLeave * call SaveLastWindow()
augroup END

function! LastWindow()
  exe "split " . g:lastWinName
endfunction

command -nargs=0 LastWindow call LastWindow()

nmap _u :LastWindow<CR>
nmap _U :call fzf#vim#cust_history(g:lastWindows)<CR>

in autoload/fzf/vim.vim add

function! fzf#vim#cust_history(src,...)
  return s:fzf('history-files', {
  \ 'source':  a:src,
  \ 'options': ['-m', '--header-lines', !empty(expand('%')), '--prompt', 'Hist> ']
  \}, a:000)
endfunction