Guard packadd to not load an optional non-existent package

Question

I have an "optional" plugin that depends on python (pack/habamax/opt/myplugin)

in my settings I have the following:

if has('python') || has('python3')
    do some setup
    packadd myplugin
endif

This thing fails if there is no myplugin though.

Is there a way I can add to an if statement to check if myplugin exists? if packexists('myplugin')?

I can probably have a try catch to suppress errors but the thing is that there might be elseif:

" if there is package myplugin and all dependencies
if has('python') || has('python3')
    do some setup
    packadd myplugin
else
"use another plugin without dependencies
    do some setup
    packadd anotherplugin
endif

@Matt,

UPDATE

Thanks for the help.

I end up using silent! packadd ...:

" try to load myplugin first
if has('python') || has('python3')
    do some setup
    silent! packadd myplugin
endif

"use another plugin without dependencies
if !exists("g:myplugin_loaded")
    do some setup
    packadd anotherplugin
endif

Answer 1

You could just

silent! packadd <plugin>

Answer 2

You can use :h exists() to test if a variable, a command or a function provided by the plugin is defined. If it is defined then it means the plugin is available:

exists({expr})  The result is a Number, which is |TRUE| if {expr} is
        defined, zero otherwise.

        The {expr} argument is a string, which contains one of these:
            &option-name    Vim option (only checks if it exists,
                    not if it really works)
            [...]
            *funcname   built-in function (see |functions|)
                    or user defined function (see
                    |user-functions|). Also works for a
                    variable that is a Funcref.
            [...]
            :cmdname    Ex command: built-in command, user
                    command or command modifier |:command|.
                    Returns:
                    1  for match with start of a command
                    2  full match with a command
                    3  matches several user commands
                    To check for a supported command
                    always check the return value to be 2.

So the idea is to check for something defined by the plugin. For example if you want to test that GitGutter is installed you can check for the g:loaded_gitgutter variable it defines like this:

if (exists('g:loaded_gitgutter'))
    nnoremap <C-L> :nohlsearch\|GitGutter<CR><C-L>
endif

Note that most of the plugins should defined a variable of the form g:loaded_pluginname as @Rich pointed out in the comments.

Answer 3

You can also use a try/catch block and a local variable to control whether you managed to load it successfully.

let has_myplugin = 0
" if there is package myplugin and all dependencies
if has('python') || has('python3')
    do some setup
    try
        packadd myplugin
        let has_myplugin = 1
    catch /^Vim\%((\a\+)\)\=:E919:/
        " Directory not found in packpath.
        " Fallback to the ! has_myplugin case.
    endtry
endif

if ! has_myplugin
    " use another plugin without dependencies
    do some setup
    packadd anotherplugin
endif

Also consider that you might want to use packadd! if you're doing it from your vimrc file. From :help :packadd:

When the optional ! is added no plugin files or ftdetect scripts are loaded, only the matching directories are added to runtimepath. This is useful in your .vimrc. The plugins will then be loaded during initialization, see load-plugins.

(See also: :help :packloadall.)